Re: PPI replacing/updating a stub

What's going on behind the scenes is actually pretty interesting. So when you say PPI::Document->new(\$sub_h{$name}{content})->find_first('PPI::Statement::Sub'), you're creating a new document, however, you're not keeping a reference to that document, so it is immediately DESTROYed - which clobbers every element of that document - including the sub returned from find_first!

So to fix that, split that statement into two, saving the document in a variable so that it is not immediately destroyed. But the code still doesn't work, because that document is still getting destroyed at the end of the loop body, removing the elements before you get to save. So to fix that, you need to disassociate the sub element from its document via remove.

There's one more minor issue, which is that you need to remove the stub, since you're replacing it with the stored one. So putting all that together gets you this, which works (file after should be identical to before):

#!/usr/bin/env perl
use warnings;
use strict;
use 5.010;
use PPI;

my $raw = <<'__RAW__';
package FeeFi;
sub Fee {
    print "Fee\n";
}
sub Fi {
    print "Fi\n";
}
1;
__RAW__

my %sub_h;
{
    my $document = PPI::Document->new(\$raw)
        or die "oops!";
    $document->save('before');
    for my $sub (@{$document->find('PPI::Statement::Sub') || []}) {
        next if $sub->forward;
        $sub_h{$sub->name}{content} = $sub->content;
        my @elements = $sub->block->children;
        for (my $i=0; $i < @elements; $i++) {
            $elements[$i]->remove;
        }
    }
    $sub_h{''}{content} = $document->content;
}
{
    my $document = PPI::Document->new(\$sub_h{''}{content})
        or die "oops creating ''!";
    for my $stub (@{$document->find('PPI::Statement::Sub') || []}) {
        next if $stub->forward;
        # 1. store the document in its own variable
        my $doc = PPI::Document->new(\$sub_h{$stub->name}{content});
        my $sub = $doc->find_first('PPI::Statement::Sub');
        # 2. remove the sub element from its document
        $stub->insert_after($sub->remove)
            or warn "Can't insert_after!";
        # 3. remove the stub
        $stub->remove;
    }
    $document->save('after');
}
[download]

Comment on Re: PPI replacing/updating a stub Select or Download Code

Replies are listed 'Best First'.
Re^2: PPI replacing/updating a stub by clueless newbie (Curate) on Sep 24, 2017 at 18:47 UTC
Thank you very much!	[reply]