An alternative would be to test the file type first and then choose the correct parser. For example

#!/usr/bin/perl
use strict;
use File::MMagic;
use Spreadsheet::ParseXLSX;
use Spreadsheet::ParseExcel;

my $FileToOpen = 'c:/temp/myfile.xlsx';

my $ft = File::MMagic->new();
my $type = $ft->checktype_filename($FileToOpen);
my $parser;

if ($type =~ /zip/){
  $parser = Spreadsheet::ParseXLSX->new();
} else {
  $parser = Spreadsheet::ParseExcel->new();
}

my $workbook = $parser->parse($FileToOpen);
if ( !defined $workbook ) {
  die $parser->error(), ".\n";
}
printf "%s has %d sheets\n",$FileToOpen,$workbook->worksheet_count();
[download]

What errors do you get? Maybe they are trying to tell you something?

Hello gauss76,

You can also try Spreadsheet::Read, there is also a nice short tutorial about it How to read an Excel file in Perl.

But to be honest most likely the error that you are getting will tell you what is wrong with your file. Try to create a new xlsx file e.g. test.xlsx insert one or two lines of data and try to open it with your script. If this works then your other file is corrupted and it can not be processed (most likely).

Hope this helps, let us know if your problem get's resolved. BR / Thanos

G'day gauss76,

Your problem starts with the first line of code you posted:

$FileToOpen=myfile.xlsx;
[download]

It seems to work as is:

$ perl -e '$FileToOpen=myfile.xlsx;'
$
[download]

But when I ask Perl to warn about problems:

$ perl -we '$FileToOpen=myfile.xlsx;'
Unquoted string "myfile" may clash with future reserved word at -e lin
+e 1.
Unquoted string "xlsx" may clash with future reserved word at -e line 
+1.
Name "main::FileToOpen" used only once: possible typo at -e line 1.
[download]

If I use strict:

$ perl -Mstrict -e '$FileToOpen=myfile.xlsx;'
Global symbol "$FileToOpen" requires explicit package name (did you fo
+rget to declare "my $FileToOpen"?) at -e line 1.
Bareword "myfile" not allowed while "strict subs" in use at -e line 1.
Bareword "xlsx" not allowed while "strict subs" in use at -e line 1.
Execution of -e aborted due to compilation errors.
[download]

If I ask Perl how it sees that code:

$ perl -MO=Deparse -e '$FileToOpen=myfile.xlsx;'
$FileToOpen = 'myfilexlsx';
-e syntax OK
[download]

[Hint: See the concatenation operator in "perlop: Additive Operators".]

Add these lines to the start of your code:

use strict;
use warnings;
[download]

Then fix all the code such that you no longer get any error or warning messages.

Use the strict and warnings pragmata in all of your code!