G'day FIJI42,

Welcome to the Monastery.

Unfortunately, ">50 columns and rows" is somewhat vague: ">50 (columns plus rows in total)"? ">50 columns and >50 rows"? something else?; also, 51 and 51,000,000 satisfy >50. In addition, providing an actual Perl data structure, for wanted or expected results, gives a much clearer picture of what you are trying to achieve.

That said, here's the technique I might have used:

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

use Text::CSV;
use Data::Dump;

die "Usage: $0 file1 file2" unless @ARGV == 2;

my ($file1, $file2) = @ARGV;
my $csv = Text::CSV::->new({sep_char => "\t"});

my $gene_data_1 = get_gene_data($file1, $csv);
my $gene_data_2 = get_gene_data($file2, $csv);
my %gene_common;

for (keys %$gene_data_1) {
    next unless exists $gene_data_2->{$_};
    push @{$gene_common{$_}}, $gene_data_1->{$_}, $gene_data_2->{$_};
} 

dd $gene_data_1;
dd $gene_data_2;
dd \%gene_common;

sub get_gene_data {
    my ($file, $csv) = @_;

    my %data;
    open my $fh, '<', $file;

    my $header = $csv->getline($fh);
    my @cols = @$header[1 .. $#$header];

    while (my $row = $csv->getline($fh)) {
        @{$data{$row->[0]}}{@cols} = @$row[1 .. $#$row];
    }

    return \%data;
}
[download]

Which outputs:

{
  Gene01 => { ColA => 5, ColB => 15 },
  Gene02 => { ColA => 4, ColB => 8 },
  Gene03 => { ColA => 25, ColB => 5 },
}
{
  Gene01 => { ColA => 12, ColC => 3 },
  Gene03 => { ColA => 5, ColC => 20 },
  Gene05 => { ColA => 22, ColC => 40 },
  Gene06 => { ColA => 88, ColC => 2 },
}
{
  Gene01 => [{ ColA => 5, ColB => 15 }, { ColA => 12, ColC => 3 }],
  Gene03 => [{ ColA => 25, ColB => 5 }, { ColA => 5, ColC => 20 }],
}
[download]

Notes (bearing in mind your "New to Perl" comment):

• You used strict. That's great, keep doing that.
• You used the "-w" switch. That's less great. Prefer the warnings pragma as recommended in "perlrun: -w".
• Consider using the autodie pragma. It saves having to handcraft your own '... or die "reason";' code, which is tedious, easy to forget or get wrong and, as such, error-prone; for instance, your current messages say what is wrong ("Can't open") but not why ("non-existent file"? "insufficient privileges"? "something else"?).
• Text::CSV is the best module to use for this (or similar, comma-separated, pipe-separated, etc.) type of data. It's already solved the types of problems typically encountered: it's not a wheel you need to reinvent. If you also have Text::CSV_XS installed, it will run faster.
• Data::Dump is only used to show the results: it's not part of the solution.
• Use the 3-argument form of open with lexical (my) filehandles. See that documentation for details.
• Use subroutines to abstract similar functions.
• See "perldata: Slices" for information on array slices (e.g. @$header[1 .. $#$header]) and hash slices (e.g. @{$data{$row->[0]}}{@cols}).