use warnings;
use strict;

my $length = 2;
my $str = "BEBEBEHUHUHUJJFAFALL";

my %cnt;
while ($str =~ /(.{$length})/g) {
    $cnt{$1}++;
}

print "Found:\n";
print "$_ $cnt{$_}\n" for sort keys %cnt;

__END__

Found:
BE 3
FA 2
HU 3
JJ 1
LL 1
[download]

This works!

Bit confused about how tho... But, thanks lad.

Hi bisimen,

the solution suggested by toolic uses regular expressions to cut the string into segments of $length (2, in this case) letters. Regular expressions are a very powerful feature of Perl that you really need to learn at some point.

However, assuming you don't know regular expressions yet, this is another way you could do it, which might be easier for you to understand:

my $str = "BEBEBEHUHUHUJJFAFALL";
my $length = 2;
my $index = 0;
my %cnt;        # hash to store the counters
while (1) {     # infinite loop
    my $substring = substr $str, $index, $length;    # getting a subst
+ring of $length length, starting at offet $index (initially 0)
    last if length($substring) < $length;            # exiting the inf
+inite loop if we are at the end of the string
    $cnt{$substring}++;                              # increasing the 
+counter for the substring
    $index += $length;                               # increasing the 
+offset by $length
}
[download]

This creates the following counters in the %cnt hash:

   'BE' => 3
   'FA' => 2
   'HU' => 3
   'JJ' => 1
   'LL' => 1
[download]

Note that this is not the way I would do it, but it is hopefully easier to understand for you, and one of Perl's favorite mottoes is: TIMTOWTDI, i.e. there is more than one way to do it.

Update: Using unpack would most probably be more efficient. Here I only wanted to show a possible process step by step.

As long as you are not allowing overlaps, an alternative to toolic's regex solution would be to use unpack.

johngg@shiraz:~/perl/Monks > perl -Mstrict -Mwarnings -E '
my $str = q{BEBEBEHUHUHUJJFAFALL};
my %cnt;
$cnt{ $_ } ++ for unpack q{(a2)*}, $str;
say qq{$_ -> $cnt{ $_ }} for sort keys %cnt;'
BE -> 3
FA -> 2
HU -> 3
JJ -> 1
LL -> 1
[download]

I hope this is of interest.

Update: A bit of a lash-up allowing for overlaps.

Is it intentional that you don't accommodate overlaps?

In other words, why is "BE" (starting at offset 0) a repeated word, but "EB" (starting at offset 1) not? Just want to make sure that's not an overlooked concern.

Hi, welcome,

Remain not in ignorance!

1. perlrequick: "the very basics"
2. perlretut: "a basic tutorial"
3. perlre: "the syntax"

(Also ... it's not "a code" -- it's a program, or alternatively a script, written in Perl (could be any computer language). The program in its written state is referred to as the "source code" or "the code.")