it's not a case of autovivification?

It is explained in perlref and for more informations see Explaining Autovivication and Autovivification in perl and https://perlmaven.com/autovivification

On CPAN there is a pragma to disable it if unwanted.

PS exists fixes your snippet: if (exists $href->{cow} and keys %{$href->{cow}}) {  # no cow

L*

Care must be used with exists as it will indeed autovivify intermediate hashes:

use strict; use warnings; use feature 'say';
use Data::Dumper; $Data::Dumper::Sortkeys = $Data::Dumper::Indent = 1;

my $href = {
    cat => { milk => 1 },
    dog => { bone => 1 },
};

say exists $href->{'cow'}->{'alfalfa'} ? 'cow' : 'no cow';

say Dumper $href

__END__
[download]

Output:

no cow
$VAR1 = {
  'cat' => {
    'milk' => 1
  },
  'cow' => {},    # uh-oh
  'dog' => {
    'bone' => 1
  }
};
[download]

So you would have to either use exists on all levels of the structure as haukex suggested:

use strict; use warnings; use feature 'say';
use Data::Dumper; $Data::Dumper::Sortkeys = $Data::Dumper::Indent = 1;

my $href = {
    cat => { milk => 1 },
    dog => { bone => 1 },
};

say exists $href->{'cow'} &&
    exists $href->{'cow'}->{'alfalfa'} ? 'cow' : 'no cow';

say Dumper $href

__END__
[download]

Output:

no cow
$VAR1 = {
  'cat' => {
    'milk' => 1
  },
  'dog' => {
    'bone' => 1
  }
};
[download]

... or use autovivification:

use strict; use warnings; use feature 'say';
use Data::Dumper; $Data::Dumper::Sortkeys = $Data::Dumper::Indent = 1;

my $href = {
    cat => { milk => 1 },
    dog => { bone => 1 },
};

no autovivification;
say exists $href->{'cow'}->{'alfalfa'} ? 'cow' : 'no cow';
say Dumper $href

__END__
[download]

Output:

no cow
$VAR1 = {
  'cat' => {
    'milk' => 1
  },
  'dog' => {
    'bone' => 1
  }
};
[download]

Note that autovivification.pm has effect lexically:

use strict; use warnings; use feature 'say';
use Data::Dumper; $Data::Dumper::Sortkeys = $Data::Dumper::Indent = 1;

my $href = {
    cat => { milk => 1 },
    dog => { bone => 1 },
};

{
    no autovivification;
    say exists $href->{'cow'}->{'alfalfa'} ? 'cow' : 'no cow';
    say Dumper $href
}

say exists $href->{'cow'}->{'alfalfa'} ? 'cow' : 'still no cow';
say Dumper $href;

__END__
[download]

no cow
$VAR1 = {
  'cat' => {
    'milk' => 1
  },
  'dog' => {
    'bone' => 1
  }
};

still no cow
$VAR1 = {
  'cat' => {
    'milk' => 1
  },
  'cow' => {},    # uh-oh
  'dog' => {
    'bone' => 1
  }
};
[download]



The way forward always starts with a minimal test.

Thanks - no autovivification will become a permanent presence for me, next to use strict.

This is "autovivification" and was just discussed the other day, see the replies in the thread Array dereference in foreach(), including the ones deeper down in the thread.

Use exists to check if a hash key exists. As described in its documentation, if you have multi-level data structures (hashes of hashes), you need to check every level. Update: Discipulus just updated to show an example.

FYI, while keys %hash returns the number of keys in scalar context, you can also use the hash itself, the value will be false if the hash is empty and true otherwise (actually 0 when empty, and information on the content otherwise). So if (exists $href->{cow} and %{ $href->{cow} }). Unlike the keys version, scalar %{ $href->{cow} } will not create a new hash (autovivify) if the cow key doesn't exist, but die instead (at least if you forgot to check if the key exists, you'll get an error in the right place).