TIMTOWTDI. Here's one with split and join:

use strict;
use warnings;

use Test::More tests => 3;

my $in = 'Mary had a little lamb';

is (nwords ($in, 1), 'Mary');
is (nwords ($in, 2), 'Mary had');
is (nwords ($in, 3), 'Mary had a');

sub nwords {
    my ($src, $num) = @_;
    return join " ", (split (/ /, $src, $num + 1))[0 .. $num - 1];
}
[download]

Essentially the same as 1nickt's approach, except the regex for a word is defined in one place so you can play with it until you get it right, and matches are extracted to an array:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $str = 'mary had a little lamb';
 ;;
 my $word = qr{ [[:alpha:]]+ }xms;
 ;;
 my @words = ($str =~ m{ $word }xmsg)[0 .. 2];
 dd \@words;
"
["mary", "had", "a"]
[download]

Hi, $str is a variable, maybe you meant substr?

Try this:

 $ perl -Mstrict -wE 'my $str = "mary had a little lamb"; say for ($st
+r =~ /(\S+)/g)[0..2]'
[download]

Hope this helps!

I note that your expected output retains the trailing space after the third word. If that was intentional then you could use a regular expression that uses zero-width look-around assertions to match the starting position of each word, recording them in an array using pos. You can then use substr to pull out everything up to the start of the first word you wish to discard.

johngg@shiraz:~/perl/Monks > perl -Mstrict -Mwarnings -E '
my @strs = (
   q{Mary had a little lamb},
   q{  its fleece was white as snow},
   );
my $nWords = 3;
my $qrWordStart = qr{(?x)
   (?: (?<= \A ) | (?<= \W ) )  # Preceded by either beginning of
                                #   string or non-word character
   (?= \w )                     # Followed by a word character
   };

foreach my $str ( @strs )
{
    my @posns;
    push @posns, pos $str
       while $str =~ m{$qrWordStart}g;
    say  qq{->@{ [ substr $str, 0, $posns[ $nWords ] ] }<-};
}'
->Mary had a <-
->  its fleece was <-
[download]

I hope this is of interest.

Update: Added information about using look-arounds and commented the regex accordingly.