in reply to Simplify HoH code

Note that given/when and smart matching is considered experimental, and might change in future releases of Perl (this is in fact currently being discussed). In this case, your conditions are so simple that they could be replaced by a simple if/elsif. That's also how I would suggest solving your question about matching multiple variables at once, e.g. if ($month eq 'FEB' && $week eq 'W1').

Also, one thing to "simplify" the code would be to use consistent formatting (like where you put the braces) and indentation. perltidy could help you with this.

Lastly, is this code really representative of your actual code? The reason I ask is that you have variables named like $FEB_L1_W1. I see two possibilities: Either you have a fixed set of variables for specific months that won't change. In that case, you don't need to loop over the keys of %Hash to find those months - just say $Hash{FEB} and $Hash{APR} to access those.

Or, you are planning your actual code to have a bunch more variables named $MONTH_L1_W1 etc. In that case, you shouldn't store them as individual variables, but instead be putting those in a hash as well, in which case you can get rid of the repetitive code in the loop and loop over both hashes. We could probably show an example of this, but at the moment I don't quite understand what your code is doing (probably because you haven't explained the magic numbers in your code).

If you could explain more about what your code is supposed to be doing, and show an SSCCE that is perhaps more representative, and some more sample input and the expected output, then we could probably help more and suggest better solutions.

Replies are listed 'Best First'.
Re^2: Simplify HoH code
by greetsathya (Initiate) on Dec 03, 2017 at 11:11 UTC
    Firs thanks for quick reply. Yes , initially i had if else instead of given/when . I switched to given/when later maybe bad choice :( i will use perltidy for formatting. Actual content will be in that format. Ok to have hash there too insteadof bunch of variables but considering HoH loops & nested ifs, Not sure to check with this new hash against HoH second loop. i added updated script with few more variables and if checks and comment on exit/print information from perltidy output: 
    #!/usr/bin/perl
use warnings;
use strict;
use feature "switch";

my %Hash = ();
$Hash{"FEB"}{"W1"} = 10.14;
$Hash{"FEB"}{"W2"} = 11.22;
$Hash{"MAR"}{"W1"} = 33.17;
$Hash{"MAR"}{"W2"} = 44.44;
$Hash{"APR"}{"W1"} = 55.00;
$Hash{"APR"}{"W2"} = 66.66;

my $FEB_L1_W1 = 11;
my $FEB_U1_W1 = 12.05;
my $FEB_L1_W2 = 13.06;
my $FEB_U1_W2 = 13.06;
my $APR_L1_W1 = 1;
my $APR_U1_W1 = 20;
my $APR_L1_W2 = 33;
my $APR_U1_W2 = 13.02;
my $MAR_L1_W1 = -12.05;
my $MAR_U1_W1 = -14.0;
my $MAR_L1_W2 = 22.0;
my $MAR_U1_W2 = -13.02;

for my $month ( keys %Hash ) {
    print "$month: ";
    for my $week ( keys %{ $Hash{$month} } ) {
        print "$week=$Hash{$month}{$week} \n";

        # Did you mean to hashloop for values here instead of hardcode
+d variable names?
        if ( $month eq "FEB" ) {
            if ( $week eq "W1" ) {
                if (    ( $FEB_L1_W1 <= $Hash{$month}{$week} )
                    and ( $Hash{$month}{$week} <= $FEB_U1_W1 ) )
                {
                    print
"month $month has f status for  $week: $Hash{$month}{$week}\n";
                }
                else {
                    print "error: print something";
                }
            }
            elsif ( $week eq "W2" ) {
                if (    ( $FEB_L1_W2 <= $Hash{$month}{$week} )
                    and ( $Hash{$month}{$week} <= $FEB_U1_W2 ) )
                {
                    print
"month $month has f status for  $week: $Hash{$month}{$week}\n";
                }
                else {
             # print error key/value : $month $Hash{$month} $Hash{$mon
+th}{$week}
             # get exit code
                }
            }
        }
        if ( $month eq "MAR" ) {
            if ( $week eq "W1" ) {
                if (    ( $MAR_L1_W1 <= $Hash{$month}{$week} )
                    and ( $Hash{$month}{$week} <= $MAR_U1_W1 ) )
                {
                    print
"month $month has f status for  $week: $Hash{$month}{$week}\n";
                }
                else {
             # print error key/value : $month $Hash{$month} $Hash{$mon
+th}{$week}
             # get exit code
                }
            }
            elsif ( $week eq "W2" ) {
                if (    ( $MAR_L1_W2 <= $Hash{$month}{$week} )
                    and ( $Hash{$month}{$week} <= $MAR_U1_W2 ) )
                {
                    print
"month $month has f status for  $week: $Hash{$month}{$week}\n";
                }
                else {
             # print error key/value : $month $Hash{$month} $Hash{$mon
+th}{$week}
             # get exit code
                }
            }
        }
    }
}

    [download]
[reply]
[d/l]

      Do I understand correctly that the variables named *_L1_* are lower limits and *_U1_* are upper limits? Although pme has shown code very similar to what I was thinking, the key thing to note is that you can restructure your $FEB_L1_W1 variables into a hash, and then see the similarity in the data structures (Data::Dumper or Data::Dump can also be helpful here).

      my %months = (
    FEB => { W1 => 11.14,
             W2 => 11.22, },
    MAR => { W1 => 33.17,
             W2 => 44.44, },
    APR => { W1 => 55.00,
             W2 => 66.66, },
);
my %limits = (
    FEB => { W1 => { L1 =>  11,    U1 =>  12.05 },
             W2 => { L1 =>  13.06, U1 =>  13.06 }, },
    APR => { W1 => { L1 =>   1,    U1 =>  20    },
             W2 => { L1 =>  33,    U1 =>  13.02 }, },
    MAR => { W1 => { L1 => -12.05, U1 => -14.0  },
             W2 => { L1 =>  22.0,  U1 => -13.02 }, },
);

      [download]

      And then notice you can create loops to loop over both at the same time, like in the following. Note I've made a few assumptions, like that limits for a certain month may not exist, but when they do, both the keys U1 and L1 are defined. If your input data varies, you may have to adjust this.

      for my $mon ( sort keys %months ) {
    for my $week ( sort keys %{ $months{$mon} } ) {
        if ( exists $limits{$mon} && exists $limits{$mon}{$week} ) {
            my $value = $months{$mon}{$week};
            my $upper = $limits{$mon}{$week}{U1};
            my $lower = $limits{$mon}{$week}{L1};
            printf "%6.2f <= %6.2f <= %6.2f - ",
                    $lower,  $value,  $upper;
            if ( $value >= $lower && $value <= $upper ) {
                print "OK\n";
            }
            else {
                print "NOT ok\n";
            }
        }
        else { warn "No limits for month $mon / week $week\n" }
    }
}

      [download]

      Which gives the following output. Note I tweaked the input slightly to give at least one "OK" output.

        1.00 <=  55.00 <=  20.00 - NOT ok
 33.00 <=  66.66 <=  13.02 - NOT ok
 11.00 <=  11.14 <=  12.05 - OK
 13.06 <=  11.22 <=  13.06 - NOT ok
-12.05 <=  33.17 <= -14.00 - NOT ok
 22.00 <=  44.44 <= -13.02 - NOT ok

      [download]
[reply]
[d/l]
[select]
        Hi, Nice one. missed the logic on getting values without looping when i have another hash. Thanks haukex & pme .
[reply]

In Section Seekers of Perl Wisdom