Keep a tally:

#!/perl/bin/perl

use strict;
use warnings;

my @files = <c:/perl64/myfiles/*>;
my $total = 0;

foreach my $file ( @files ) {

    open my $file_h, '<', $file or die "Can't open $file: $!";

    while ( <$file_h> ) {

        if (/\b120[347]\b/) {

            print "$file $_";
            $total++;
        }
    }
}
print "No files matched.\n" unless $total;
[download]

(Edited for typos)

I think they wanted to check for each number separately. But this is most of the way there -- I'd just add a hash for the match, something like $matched{$1} = 1, and check that at the end.

-QM
--
Quantum Mechanics: The dreams stuff is made of

Hmmm. Yes, you could well be right about each one requiring a separate flag, although that's not how I originally read the requirement. At least our anonymous brother has 2 marginally differing approaches to choose between. The whole thing does have something of an XY ring to it. Perhaps we'll find out.

#!/usr/bin/env perl

use strict;
use warnings;

my @files = <c:/perl64/myfiles/*>;

# record matching regexes
our %matched;

my @nums = ('1203', '1204', '1207');
my $regex = '\b(' . join('|', @nums) . ')\b'; # update: fixed + to .

for my $file ( @files ) {

    open my $file_h, '<', $file or die "Can't open $file: $!";

    while ( <$file_h> ) {
        if (my ($match) = m/$regex/) {
            $matched{$match} = 1;
            print "$file $_";
        }
    }
}

# Check all nums have been seen
for my $num (@nums) {
    if (not exists($matched{$num})) {
        print "$num not found\n";
    }
}
[download]

I would probably remove the @files and pass them on the command line (changing the for loop to while (<>)).

You might also do something more generic around the numbers, and allow those to be passed on the command line as well -- but this will take some command line parsing, or one of the GetOpt modules.

Update: Fixed capture problem, as noted by AnomalousMonk.

my @nums = ('1203', '1204', '1207');
my $regex = '\b(?:' + join('|', @nums) + ')\b';
[download]

No way is provided for  if (my ($match) = m/$regex/) { ... } to capture anything (and thus be true). Also, only a single match per line is assumed. (Also  + (addition) is used where  . (concatenation) is intended.)

I would suggest something along the lines of

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @nums = ('1203', '1204', '1207');
 my $regex = '\b(?:' . join('|', @nums) . ')\b';
 print qq{'$regex'};
 ;;
 my @matches = 'w 1207 x 1203 y 9999 z' =~ m{ $regex }xmsg;
 dd \@matches;
"
'\b(?:1203|1204|1207)\b'
[1207, 1203]
[download]

with the loop being (also untested):

while ( <$file_h> ) {
  if (my @matches = m/$regex/g) {
    ++$matched{$_} for @matches;
    print "$file $_";
  }
}
[download]

Update: Changed code example to include 9999 group.

Update 2: Shorter, IMHO sweeter:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @nums = qw(1203 1204 1207 1111);
 my ($regex) = map qr{ \b (?: $_) \b }xms, join ' | ', @nums;
 print $regex;
 ;;
 my %seen;
 for ('w 1207 x 1203 y 9999 z',
      'w 11203 x 12033 y 112033 z',
      'w 1207 x 1203 y 9999 z 1207 zz',
     ) {
   print qq{>$_<} if map ++$seen{$_}, m{ $regex }xmsg;
   }
 dd \%seen;
 ;;
 my $not_seen = join ' ', grep !$seen{$_}, @nums;
 print 'num(s) not seen: ', $not_seen || '(none)';
"
(?msx-i: \b (?: 1203 | 1204 | 1207 | 1111) \b )
>w 1207 x 1203 y 9999 z<
>w 1207 x 1203 y 9999 z 1207 zz<
{ 1203 => 2, 1207 => 3 }

num(s) not seen: 1204 1111
[download]

---

Give a man a fish:  <%-{-{-{-<

Ah, yes, I started down one path, then changed tacks.

I believe if you change this line:

my $regex = '\b(?:' . join('|', @nums) . ')\b'; # update: fixed concat
+enation issue
[download]

to this:

my $regex = '\b(' . join('|', @nums) . ')\b'; # update: fixed concaten
+ation issue
[download]

it does the job.

For instance, from the debugger (which, note, doesn't play well with my):

DB<1> $_ = "oh blah dee"
DB<2> ($x) = m/(blah)/
DB<3> x $x
0  'blah'
[download]

Update: Fixed concatenation issue

-QM
--
Quantum Mechanics: The dreams stuff is made of

This is how I would do it:

# *perl*
use strict; use warnings;
use Getopt::Std;

our ($opt_n, $opt_g);
getopt('n');

if (! $opt_n || ! $opt_g) {
    print "usage: $0 -n numberlist -g globpattern\n"
        . "  where numberlist are numbers separated by commas,\n"
        . "  e.g. -n 1203,0815,22222\n";
    exit;
}
my %matches;
$matches{$_} = 0 for split /,/, $opt_n;
$opt_n =~ s/,/|/g;
my $re = qr{\b($opt_n)\b};

@ARGV = <$opt_g>; # set @ARGV to found files 

while(<>) {
    my @m;
    @m = $_ =~ /$re/g and @matches{@m} = (1) x @m and print "$ARGV $_"
+;
}

my @nomatch = grep { ! $matches{$_} } keys %matches;
if(@nomatch) {
    print "$_ not matched\n" for @nomatch;
}
[download]

C:\some\path>perl match.pl -n 1203,1204,1207 -g c:/perl64/myfiles/*
[download]

Of course, TIMTOWTDI (there is more than one way to do it)