Note that my ($self,$x) = shift; is not correct, it should be my ($self,$x) = @_; instead (several times in your code).

While it is possible to do what you want (Method Names as Strings), it seems like it might not be a good idea, and instead be the beginning of a bad design pattern - if you could explain why you think you need this and what you want to accomplish, perhaps we can suggest a better approach.

use warnings;
use strict;
{
    package A;
    sub new { bless {}, shift }
    sub _exe {
        my $self = shift;
        my $meth = shift;
        $self->$meth(@_);
    }
}
{
    package B;
    use base 'A';
    sub new { bless {}, shift }
    sub _what {
        my $self = shift;
        $self->_exe('_print', @_);
    }
    sub _print {
        my ($self, @args) = @_;
        print @args, "\n";
    }
}
my $b = B->new;
$b->_what("foo","bar");  # prints "foobar"
[download]

First of all thank you for your answer, i get it now. Second, i know about my errors i wrote the post too quickly (in a bit of a time squeeze so read it as a pseudo code) And Third, I am always on a lookout for a better way (especially if there is already a solution ):).

Genera idea is to have an execution class that checks whether the execution passed to it, is simply a system command or a function or an object method. For example let say I am programming something and i need to execute a cmd but i do not want to know how to handle errors, exceptions etc... so I pass it to a class that executes the cmd and returns me an error/result/warning. But sometimes I do not want to pass a system cmd, I want to implement the command in my own function (with parsing) and still use the same module to check for errors/results/exceptions. Moreover, let say maye I know how to OOp (I don't but...) so I don't have a regular function but my methods are encapsulated/members of my own classes which again I want to pass to this third party module and get errors/warnings etc... back.

Is there anything like that out there. I surveyed for this for couple weeks not and could not find a universal solution .

i know about my errors i wrote the post too quickly (in a bit of a time squeeze so read it as a pseudo code)

If you're in a hurry, the best way to get quick answers is to post well-formed questions. Forcing others to fix irrelevant errors in your code can make people less willing to help.

Anyway, I am about 80% sure I understood what you want to do :-) It sounds like the situation you are describing would probably be appropriate for dynamic method calls, but what is still a bit unclear is how you want to handle errors. I think this is relevant for two reasons: First, different functions/methods will throw errors differently - some return undef, some return a negative number, some die, system commands usually return 0 on success, etc. Second, personally I think that in many cases, the best place to handle errors is on the outermost layer of the program, instead of somewhere deep inside several layers - I have seen overuse of try/catch to suppress relevant errors too often. And you might want to consider that designing a new general dispatch mechanism is not something you want to do in a time squeeze, perhaps it's better to reach for existing tools.

If you are looking for a general exception handling mechanism, a place to start might be Try::Tiny.

If by "system command" you mean external programs, then there are several modules to do that with, one of them is my own IPC::Run3::Shell. You can even inherit from IPC::Run3::Shell::Autoload, here's an example where cat is implemented by a method in the package, and any other method calls are autoloaded and turned into system commands, for example the method tac calls the external program tac:

#!/usr/bin/env perl
use warnings;
use strict;
use IPC::Run3::Shell ':FATAL';
use Try::Tiny;

{
    package Runner;
    BEGIN { our @ISA = ('IPC::Run3::Shell::Autoload') };
    sub new { bless {}, shift };
    sub cat {
        my ($self,$filename) = @_;
        open my $fh, '<', $filename or die "cat $filename: $!";
        while (<$fh>) {
            print "cat: $_";
        }
        close $fh;
    }
}

my $r = Runner->new;
$r->cat('/tmp/test.txt');
$r->tac('/tmp/test.txt');
try {
    $r->cat('/tmp/notexist');
}
catch {
    warn "Failed: $_";
};
try {
    $r->tac('/tmp/notexist');
}
catch {
    warn "Failed: $_";
};

__END__

cat: Foo
cat: Bar
cat: Quz
Quz
Bar
Foo
Failed: cat /tmp/notexist: No such file or directory at shell.pl line 
+13.
tac: failed to open ‘/tmp/notexist’ for reading: No such file or direc
+tory
Failed: Command "tac" failed: exit status 1 at shell.pl line 31.
[download]

BTW, my ($self, $y) = shift; isn't a typo, it is wrong IMHO. It should be my ($self, $y) = @_; - if this is what you meant.

See also shift and perlsub.

Best regards, Karl