grep returns all the elements in a list that match a condition, so potentially several elements. You are trying to retrieve a single information (scalar value) from something that can potentially return many, so perl being what it is (it likes to guess what you mean), it guesses that the single information that you want out of that all process is the number of matches.

You should write something like my @stockvals = grep { /a2/ } @array; instead, and check that @stockvals only has one element. Or, if you're really confident, you can write: my ($stockval,) = grep{/a2/} @array;, because of the parentheses the left part is now a list (of only one element, but still a list), and copying a list of data to a list makes sense.

Trying to get a single value is actually called "scalar context", and a list of values "list context". So you can see in grep's documentation that: "In scalar context, returns the number of times the expression was true."

Edit: I answered your specific problem (why isn't grep giving you the value you expect), but I think thanos1983's proposition is a better solution to your overall problem, because once you have filled the hash with the input information, you can easily access any element, while grepping will have to be done for each element on the whole array.

Eily - I should have used @stockvals as opposed to attempting to stuff it into a scalar, thanks.

Hello Gtforce,

You can use something like that:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;
use feature 'say';

my @array = ("a1 b1", "a2 b2", "a3 b3", "a5 b5", "a4 b4");

my %hash;
foreach my $element (@array) {
    my ($key, $value) = split(/ /, $element, 2);
    $hash{$key} = $value;
}

print Dumper \%hash;

say $hash{'a5'};

__END__

$ perl test.pl
$VAR1 = {
          'a3' => 'b3',
          'a5' => 'b5',
          'a4' => 'b4',
          'a2' => 'b2',
          'a1' => 'b1'
        };
b5
[download]

What I did above is split each array element based on space between strings. Then simply I used the first element as a key to the hash and the second as the value.

Update: If you prefer one liner:

my %hash = map { split( / /, $_, 2 ) } @array;
[download]

Hope this helps, BR.

Many thanks, Thanos (runs way faster than what I expected)

Hello again Gtforce,

Since you are also interested in speed and resources here is a small Benchmark measurement including three different ways of resolving your problem:

Read more... (2 kB)

A minor note here, if you use while loop it is a bit faster than foreach loop but it destroys the array.

In conclusion on this case map looks to be the best option and it can be put it like this on a function:

Read more... (503 Bytes)

Hope this helps, BR.

Seeking for Perl wisdom...on the process of learning...not there...yet!

@array = ("a1 b1","a2 b2","a3 b3","a5 b5","a4 b4");
print "product?\n";
chomp($prod = <>);
foreach(@array){
    @items = split(/ /,$_);
    if($items[0] eq $prod){
        print $items[1];
    }
}
[download]