in reply to Re^3: problem with show_values => 1, while drawing a bar graph with variables
in thread problem with show_values => 1, while drawing a bar graph with variables

Hi, thanks for your reply. I succeeded with below.Now, it's OK. 

$clean_total =~ s/^\s+|\s+$//g;
$spam_total =~ s/^\s+|\s+$//g;
$virus_total =~ s/^\s+|\s+$//g;
$banned_total =~ s/^\s+|\s+$//g;
$badheader_total =~ s/^\s+|\s+$//g;
$reject_total =~ s/^\s+|\s+$//g;

[download]
Anyway, I checked with chomp($clean_total) as well. It also worked. Anyway, what is better? Here's my code 


#!/usr/bin/perl

use CGI;
use CGI qw(:standard);

use strict;
use warnings;
 
use GD;
use GD::Graph;
use GD::Graph::bars;
use GD::Graph::Data;

$ENV{"PATH"} = "/usr/sbin:/usr/bin:/sbin:/bin";


print "Content-type: text/html\n\n";
print "<body bgcolor=\"#95B8DB\">";

print "<br />";

print "<h1 align=center>\n";
print "Global Mail Statistics\n";
print "</h1>\n";

print "<br />";
print "<br />";

my $str = qx(date);
print $str;

print "<br />";

#Passed CLEAN - Clean Mails

my $clean_total = qx(sudo grep -Ec 'amavis.*Passed CLEAN' /var/log/mai
+llog);
#chomp($clean_total);
$clean_total =~ s/^\s+|\s+$//g;

#Blocked SPAM - Spam Mails

my $spam_total = qx(sudo grep -Ec 'amavis.*Blocked SPAM' /var/log/mail
+log);
#chomp($spam_total);
$spam_total =~ s/^\s+|\s+$//g;

#Blocked INFECTED - Virus Mails

my $virus_total = qx(sudo grep -Ec 'amavis.*Blocked INFECTED' /var/log
+/maillog);
#chomp($virus_total);
$virus_total =~ s/^\s+|\s+$//g;

#Blocked BANNED - Banned Mails exe,scr etc.

my $banned_total = qx(sudo grep -Ec 'amavis.*Blocked BANNED' /var/log/
+maillog); 
#chomp($banned_total);
$banned_total =~ s/^\s+|\s+$//g;

#BAD-HEADER- - Bad Header Mails

my $badheader_total = qx(sudo grep -Ec 'amavis.*BAD-HEADER-' /var/log/
+maillog);
#chomp($badheader_total);
$badheader_total =~ s/^\s+|\s+$//g;

#REJECT - REJECT Mails

my $reject_total = qx(sudo grep -c 'reject' /var/log/maillog);
#chomp($reject_total);
$reject_total =~ s/^\s+|\s+$//g;

print "<br />";


my $data = GD::Graph::Data->new([
    ["Cleaned","Spam","Virus","Banned","BadHeader","Rejected"],
    [     $clean_total,    $spam_total,    $virus_total,    $banned_to
+tal,    $badheader_total,  $reject_total],
]) or die GD::Graph::Data->error;

 
#my $data = GD::Graph::Data->new([
#    ["Cleaned","Spam","Virus","Banned","BadHeader","Rejected"],
#    [10, 36, 0, 0, 0, 974],
#]) or die GD::Graph::Data->error; 

 
my $graph = GD::Graph::bars->new(600,300);
 
$graph->set( 
    x_label         => 'Category',
    y_label         => 'Count',
    title           => 'Global Mail Statistics',

    # Show values on top of each bar
    show_values => 1,
 
    #y_max_value     => 7,
    y_tick_number   => 8,
    #y_label_skip    => 3,
 
    #x_labels_vertical => 1,
    #show_values => 1,
    #values_vertical => 1,
    #values_space=> 4,
 
    bar_spacing     => 10,
    shadow_depth    => -4,
    shadowclr       => 'dred',
 
    transparent     => 0,

) or die $graph->error;

$graph->set_title_font("/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf",1
+4);
$graph->set_x_axis_font("/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf",
+8);
$graph->set_y_axis_font("/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf",
+8);
$graph->set_x_label_font("/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf"
+,12);
$graph->set_y_label_font("/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf"
+,12);

$graph->plot($data) or die $graph->error;

my $file = 'bars.png';
open(my $out, '>', "../../../tmp/$file") or die "Cannot open '$file' f
+or write: $!";
binmode $out;
print $out $graph->gd->png;
close $out;

system("sudo /bin/cp -pf /tmp/$file /var/www/html/");

print "<img src=../$file><p>\n"; 

print "<br />";

print "</body>";
print "</html>\n";

[download]

This works as expected. I would like to test your other perl code too.Since it is very very perl way. One more question is remaing. How can change font size of values on the top of the bar.

Replies are listed 'Best First'.
Re^5: problem with show_values => 1, while drawing a bar graph with variables
by poj (Abbot) on Mar 15, 2018 at 13:14 UTC
    How can change font size of values on the top of the bar. 
    my $font = '/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf';
$graph->set_values_font($font, 12);

    [download]
    update

    If you split the cgi into 2 scripts you can show the graphic without creating a file.

    #!/usr/bin/perl
# page.cgi
use strict;
use CGI ':standard';

print header();
print start_html(-title  =>'Global Mail Statistics',
                 -bgcolor=>'#95B8DB');
print qq!<br/><center>
<h1>Global Mail Statistics</h1>
<img src = "bargraph.cgi"></center>!;
print end_html;

    [download]
    #!/usr/bin/perl
# bargraph.cgi
use strict;
use warnings;
use CGI qw(:standard);
use GD::Graph;
use GD::Graph::bars;
use CGI::Carp 'fatalsToBrowser'; # use only for testing

my $logfile = '/var/log/maillog';
open $fh, '<', $logfile or die "Could not open $logfile : $!";
my %count=();

while (<$fh>){
  if (/amavis.*(Passed|Blocked) (CLEAN|SPAM|INFECTED|BANNED)/){
    ++$count{$2};
  } elsif (/amavis.*(BAD-HEADER)-/) {
    ++$count{$1};
  } elsif (/reject/){
    ++$count{'REJECTED'};
  }
}
close $fh;  
my @data = map{ $count{$_} || 0 } qw(CLEAN SPAM INFECTED BANNED BAD-HE
+ADER REJECTED);

my $data = GD::Graph::Data->new([
    ["Cleaned","Spam","Virus","Banned","BadHeader","Rejected"],
    [@data],
]) or die GD::Graph::Data->error; 

my $graph = GD::Graph::bars->new(900,600);
$graph->set( 
    x_label       => 'Category',
    y_label       => 'Count',
    title         => 'Global Mail Statistics for '.localtime,
    show_values   => 1,
    y_tick_number => 8,
    bar_spacing   => 10,
    shadow_depth  => -4,
    shadowclr     => 'dred',
    transparent   => 0,
) or die $graph->error;

my $font = '/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf';
$graph->set_title_font($font,14);
$graph->set_values_font($font, 12);
$graph->set_x_axis_font($font,10);
$graph->set_y_axis_font($font,10);
$graph->set_x_label_font($font,12);
$graph->set_y_label_font($font,12);

print header('image/png');
$graph->plot($data) or die $graph->error;
binmode STDOUT;
print $graph->gd->png;

    [download]
    poj
[reply]
[d/l]
[select]

      Hi, thanks for your reply. I am ok with this font size. i.e - $graph->set_values_font($font, 8). My graph is PERFECT now. I thank you again for your wonderful support. Anyway, I would like to learn below codes since I want to draw in that way. because It's a very perl way. Could you pls explain below codes. 

      
my %count=();  # A hash -it is bcos of of key/value pairs?

while (<$fh>){
  if (/amavis.*(Passed|Blocked) (CLEAN|SPAM|INFECTED|BANNED)/){
    ++$count{$2}; # Why ++$count? why {$2} here? is it bcos of (Passed
+|Blocked) ?
  } elsif (/amavis.*(BAD-HEADER)-/) {
    ++$count{$1}; # why {$1} here? is it bcos of (BAD-HEADER)
  } elsif (/reject/){
    ++$count{'REJECTED'}; #Hmm, Why {'REJECTED'}?
  }
}

      [download]

      Now I want to learn next code 

      
my @data = map{ $count{$_} || 0 } qw(CLEAN SPAM INFECTED BANNED BAD-HE
+ADER REJECTED);

Why map{ $count{$_} || 0 } ? 

qw(CLEAN SPAM INFECTED BANNED BAD-HEADER REJECTED) # here you create a
+n array for count values?

      [download]
      
my $data = GD::Graph::Data->new([
    ["Cleaned","Spam","Virus","Banned","BadHeader","Rejected"],
    [@data],
]) or die GD::Graph::Data->error; 

[@data] has count values coming from  line qw(CLEAN SPAM INFECTED BANN
+ED BAD-HEADER REJECTED)

      [download]

      Could you pls explain me these, Since I PREFER this method and I can learn a lot of perl as well.

[reply]
[d/l]
[select]
        my %count=();  # A hash -it is bcos of of key/value pairs?

        Yes, this declared a hash to store the results of counting the lines. The key will be one of either 'CLEAN','SPAM','INFECTED','BANNED','BAD_HEADER','REJECTED' and the value is the count.

        while (<$fh>){

        Read each line of the file into $_

          if (/amavis.*(Passed|Blocked) (CLEAN|SPAM|INFECTED|BANNED)/){

        Match the line read (in $_) against the regex pattern like grep. The first word captured (Passed or Block) will be in $1 and the second (CLEAN or SPAM or INFECTED or BANNED) will be in $2 

            ++$count{$2}; # Why ++$count? why {$2} here? is it bcos of (Passed
+|Blocked) ?

        [download]

        For example, if $2 is the word CLEAN increment the hash $count{'CLEAN'}

          } elsif (/amavis.*(BAD-HEADER)-/) {
    ++$count{$1}; # why {$1} here? is it bcos of (BAD-HEADER)

        [download]

        Yes, this regex has only 1 set of brackets so if it matches the word BAD-HEADER will be in $1

          } elsif (/reject/){
    ++$count{'REJECTED'}; #Hmm, Why {'REJECTED'}?
  }
}

        [download]

        I chose REJECTED because 'rejected' was the label in your graph and all the other keys are upper case

        my @data = map{ $count{$_} || 0 } qw(CLEAN SPAM INFECTED BANNED BAD-HEADER REJECTED);

        map is a convenient way of creating an array from another another array. It is the same as

        my @data=();
$data[0] = $count{'CLEAN'} || 0; # use 0 if $count{'CLEAN'} is undefin
+ed 
$data[1] = $count{'SPAM'} || 0;
$data[2] = $count{'INFECTED'} || 0;
$data[3] = $count{'BANNED'} || 0;
$data[4] = $count{'BAD-HEADER'} || 0;
$data[5] = $count{'REJECTED'} || 0;

        [download]
        poj
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom