Re: Reading from text file

Hello sarath92,

Welcome to the Monastery. Although fellow Monks have already answered your question, I wanted to add something minor. I believe you are a bit of a beginner so maybe a more analytical step by step script could help you understand how to do something similar in future for your self.

Sample of code:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my %hash;
while (<>) { # read files from command line (separate by space) e.g. i
+n.txt sample.txt etc...
    next if /^(\s*(#.*)?)?$/; # skip blank lines and comments
    chomp; # lines that are not skipped remove new line character '\n'
    my @tmp = split /:/; # split line on column ':'
    if (exists $hash{$tmp[0]}) { # check if key exists in hash
    $hash{$tmp[0]} .= ":".$tmp[2]; # if exists append
    }
    else {
    $hash{$tmp[0]} = $tmp[2]; # if not exists create new element with 
+data
    }
} continue {
    close ARGV if eof;
}

print Dumper \%hash;

open(my $fh, '>', 'out.txt') # open file to print data
    or die "Could not open file 'out.txt' $!";

while( my( $key, $value ) = each %hash ){ # iterate over the hash
    print $fh $key.':'.$value . "\n"; # write data to file
}

close $fh # close file after finishing
    or warn "Could not close file 'out.txt' $!";

__END__

$ perl test.pl in.txt
$VAR1 = {
          'Thailand' => '6',
          'China' => '2:2:70',
          'Japan' => '6:10'
        };

$ cat out.txt
Thailand:6
China:2:2:70
Japan:6:10
[download]

Hope this helps, BR.

Seeking for Perl wisdom...on the process of learning...not there...yet!

Comment on Re: Reading from text file Select or Download Code

Replies are listed 'Best First'.
Re^2: Reading from text file by Marshall (Canon) on Mar 23, 2018 at 16:49 UTC
I guess we are doing the Op's work for him. But I will make a few comments to your code. See a refactored version below. First, I would name the hash according to what the values mean. Unfortunately the OP didn't tell that key piece of info. Then we could have wound up with something like: `$meanful_name{$country}` I think a hash of array would be better here than a string as the value. This would among other things allow easy sorting of the values. They happen to be sorted in the example data, but sorting would be possible with an array. With the HoA, there is not need to check if the key exists. Perl would create it automatically. In your code, you do have to be sure that the key exists or the concatenation will throw an error. I think a better way to accomplish that would be: `$hash{$tmp[0]} //= '';` This is a new operator in Perl 5.10 that sets the hash value to '' if it is not already defined. That way we eliminate the "if/else" statement and the concatenate case becomes the only one. In Perl, often constructs like `$temp[0]` wind up being strangely absent. That is because we can assign meaningful names right away with a list slice. Shown below. It is also possible to use "undef" as a left hand side value, like `($country,undef,$num)` That is an alternate way of "throwing something away". Hope this helps. #!/usr/bin/perl use strict; use warnings; my %country_hash; while (<DATA>) { next if /^(\s(#.)?)?$/; # skip blank lines and comments chomp; # lines that are not skipped remove new line character '\n' my($country,$number) = (split /:/)[0,-1]; # split line on column ' +:' push @{$country_hash{$country}},$number; } foreach my $country (sort keys %country_hash) { print "$country:", join (":",@{$country_hash{$country}}), "\n"; } =Prints China:2:2:70 Japan:6:10 Thailand:6 =cut __DATA__ China:wd:2 Japan:wd:6 China:sg:2 Japan:sg:10 China:kng:70 Thailand:kng:6 [download]	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: Reading from text file
by Marshall (Canon) on Mar 23, 2018 at 16:49 UTC

First, I would name the hash according to what the values mean. Unfortunately the OP didn't tell that key piece of info. Then we could have wound up with something like: $meanful_name{$country}

I think a hash of array would be better here than a string as the value. This would among other things allow easy sorting of the values. They happen to be sorted in the example data, but sorting would be possible with an array.

With the HoA, there is not need to check if the key exists. Perl would create it automatically. In your code, you do have to be sure that the key exists or the concatenation will throw an error. I think a better way to accomplish that would be: $hash{$tmp[0]} //= ''; This is a new operator in Perl 5.10 that sets the hash value to '' if it is not already defined. That way we eliminate the "if/else" statement and the concatenate case becomes the only one.

In Perl, often constructs like $temp[0] wind up being strangely absent. That is because we can assign meaningful names right away with a list slice. Shown below. It is also possible to use "undef" as a left hand side value, like ($country,undef,$num) That is an alternate way of "throwing something away". Hope this helps.

#!/usr/bin/perl
use strict;
use warnings;

my %country_hash;

while (<DATA>)
{
    next if /^(\s*(#.*)?)?$/; # skip blank lines and comments
    chomp; # lines that are not skipped remove new line character '\n'

    my($country,$number) = (split /:/)[0,-1]; # split line on column '
+:'
    
    push @{$country_hash{$country}},$number;
}

foreach my $country (sort keys %country_hash)
{
    print "$country:", join (":",@{$country_hash{$country}}), "\n";
}

=Prints
China:2:2:70
Japan:6:10
Thailand:6
=cut

__DATA__

China:wd:2

Japan:wd:6

China:sg:2

Japan:sg:10

China:kng:70

Thailand:kng:6
[download]

[reply]
[d/l]
[select]