Your @stack is just an array, and you want to see them in the reverse order:

print $stack[ $_ ] for reverse 0 .. $#stack;
[download]

And if you really want to destroy the stack in the process, add:

undef @stack;
[download]

You could also do:

print while pop @stack;
[download]

But that's just wasteful :) (It's actually not, perl's arrays are well optimised for this operation.)

A little rewrite using DATA instead of an external file and a loop.

use strict;
use warnings;
#my ($a, $b, $c, $d, $e);

my $file = "data.txt";
#open(my $fh,'<', $file) or die "can't open $file $!";
#my @stack = <$fh>;
my @stack = <DATA>;
#chomp @stack;


#$a = pop @stack;
#print $a . "\n";

#$b = pop @stack;
#print $b . "\n";

#$c = pop @stack;
#print $c . "\n";

print while defined ($_ = pop @stack);

__DATA__
line 1
line 2
line 3
line 4
[download]

Result:

line 4
line 3
line 2
line 1
[download]

See also: reverse and File::ReadBackwards.

I did it this way and it worked, but it all comes out on one line and I have tried adding a new line in several areas, but I keep getting errors. Where would I add a new line character to make sure they all come out on separate lines?

Either refrain from chomping @stack or else replace print with say.

I have tried adding a new line in several areas, but I keep getting errors.

If you want help fixing errors you have to say what those errors were (precisely) and how you generated them (with an SSCCE). Just saying "I keep getting errors" is not informative enough.

Another way: Print last n lines of array in reverse order:

c:\@Work\Perl\monks>perl -wMstrict -e
"my @stack = (
   'line 1', 'line two', 'third line',
   'line the fourth', 'almost there', 'last line',
   );
 ;;
 my $n = 3;
 ;;
 print qq{$_ \n} for @stack[ -$n .. -1 ];
"
line the fourth
almost there
last line
[download]

Update: Oops... Just realized the lines are not printed in reverse order. Oh well, easily fixed (but not as neat):

c:\@Work\Perl\monks>perl -wMstrict -e
"my @stack = (
   'line 1', 'line two', 'third line',
   'third from last', 'almost there', 'last line',
   );
 ;;
 my $n = 3;
 ;;
 print qq{$_ \n} for reverse @stack[ -$n .. -1 ];
"
last line
almost there
third from last
[download]

use strict;
use warnings;

#my $file = "data.txt";
my $file = \do{my $simulated_file = "line1\nline2\nline3\nline4\n";};
# Line above simulates the file.

open (my $fh, '<', $file) or die "can't open file $!";
my @stack = <$fh>;
chomp @stack;
{
    local $, = "\n";
    print reverse( @stack ), "\n";
}
@stack = ();    # Only needed if you wish to destroy the @stack

OUTPUT:
line4
line3
line2
line1
[download]