AoA means that essentially X[0] is a reference to an array.

#!/usr/bin/perl
use strict;
use warnings;

my @X = ([0,1],[0,0,0],[1,1,1,1,1,1,1,1,1]);

#This is a ragged 2 D array

foreach my $row_ref (@X)
{
   print "num of elements this row: ", scalar (@$row_ref), "\n";
}

__END__
num of elements this row: 2
num of elements this row: 3
num of elements this row: 9
[download]

A simple array is like: @array=(1,2,3). A 2-D matrix is made up of references to arrays like that. So, essentially the first dimension of the 2D array is an array of references to other arrays that contain the actual data.

scalar @A returns the number of items in the first field. No...that would be the number of rows in the ragged 2D matrix.

You need to iterate over the top-level array, and then work on each element individually. Here's an example:

use warnings;
use strict;

my @aoa = (
    [qw(1 1 1 1)],
    [qw(2 2 2)],
    'a string',
    [qw(3 3 3 3 3 3 3)],
    {a => 1, b => 2},
);

my $index = 0;

for (@aoa){
    if (ref $_ eq 'ARRAY'){
        my $element_count = scalar @$_;
        print "elem $index has $element_count elements\n";
    }
    else {
        print "elem $index is not an array reference\n";
    }

    $index++;
}
[download]

Output:

elem 0 has 4 elements
elem 1 has 3 elements
elem 2 is not an array reference
elem 3 has 7 elements
elem 4 is not an array reference
[download]

While the prior replies are very good general answers, if you wanted to directly find the size of just the second array in the AoA @A you could use  scalar(@{$a[1]}) where $a[1] is the reference to the second list and  @{$a[1]} deferences that to an array and  scalar(@{$a[1]}) takes the size of that.

edit: opps i should have replied to the OP and not a reply, sorry

2018-05-16 Athanasius reparented to OP

my @A = ([0,1],[0,1,2,3,0],[1,2,3,4,1,1,1,11]);

my $zeroes = scalar grep { $_ == 0 } @{$A[1]};
my $ones =   scalar grep { $_ == 1 } @{$A[2]};

print "Scalar    : ", scalar @A, "\n";
print "Last index: $#A\n";
print "Zeroes in second field: $zeroes\n";
print "Ones   in third  field: $ones\n";
[download]