I agree with hippo that the keys of the %catalog hash make a decent reference, and that's probably how I would have done it, although those "references" are only like symbolic references. If you want to use "hard" references and have everything stored in one data structure, that's possible too, although there is a caveat: If you store the values of %catalog as elements of the $student{$student_id} array, you lose the key (the course number). One common solution is to additionally store the key as part of the value (often a hash reference). In the following, I'm using the property of Foreach Loops that the loop iterator variable is an alias, so that I can overwrite elements of the array by assigning to the iterator variable.

use warnings;
use strict;
use Data::Dump;

my %expensive_lookup = (
        math01 => { instructor=>'alice' },
        sci99  => { instructor=>'bob'   },
        gym55  => { instructor=>'carol' },
        cs101  => { instructor=>'larry' },
    );

my %students = (
    sid01  => [qw/ math01 gym55 /],
    sid007 => [qw/ gym55 sci99  /],
    sid42  => [qw/ cs101 math01 /],
);

my %catalog = ();

for my $student_id (keys %students) {
    for my $course_number ( @{ $students{$student_id} } ) {
        if ( not exists $catalog{$course_number} ) {
            $catalog{$course_number} =
                $expensive_lookup{$course_number};
            $catalog{$course_number}{course_number} = $course_number;
        }
        $course_number = $catalog{$course_number};
    }
}

dd \%catalog, \%students;

__END__

do {
  my $a = {
    cs101  => { course_number => "cs101", instructor => "larry" },
    gym55  => { course_number => "gym55", instructor => "carol" },
    math01 => { course_number => "math01", instructor => "alice" },
    sci99  => { course_number => "sci99", instructor => "bob" },
  };
  (
    $a,
    {
      sid007 => [$a->{gym55}, $a->{sci99}],
      sid01  => [$a->{math01}, $a->{gym55}],
      sid42  => [$a->{cs101}, $a->{math01}],
    },
  );
}
[download]

Thanks - good illustration.

(Never heard of Data::Dump -- much nicer than Dumper.)

Now I want for $student{$student_id} to be a reference to an array of references to the key/value pair stored at $catalog{$course_number}.

I don't see the need for that. Why not just store the key in the array and then use that to look up the value from %catalog whenever you need it?

push @{$students{$student_id}}, $course_id;

# ... then to retrieve later ...

for my $cid (@{$students{$student_id}}) {
    print "Course ID $cid, Tutor: $catalog{$cid}{tutor}\n"; # or whate
+ver
}
[download]

Yes, I came to that eventually! Straightforward.

I think you might be interested to do this in an object oriented way with a Student and a Course class.

For an object $student you could call a method ->enroll to add a course.

Something like print $_->instructor for $student->courses would become straight forward.

A method $student->timetable would be easily implemented.

And if you decide one day to switch to another representation of the underlying data (like SQL instead of hashes) you'll just need to change the corresponding classes.

There is no need to put a reference to a course hash table in the student structure.
Put the course hash key instead.
A Perl hash lookup is very fast..

If the number of students or courses is "small", there won't be a performance problem.
"small" in this situation is like 100,000.
If one of the tables is more than that, then an SQL DB will yield better performance.