anjultyagi:

You're creating the hash value just fine. It's just that when you pass a hash to a function, it's expanding into a list. So when Dumper runs, it's dumping each value in the list separately, so it doesn't look like what you're expecting. Here's an example:

$ cat u.pl
use strict;
use warnings;
use Data::Dumper;

my $hashRef = {amountSubmitted=>1};
print "a hash reference: ", Dumper($hashRef), "\n";

my %hash = (amountSubmitted=>0);
print "a hash expands to a list: ", Dumper(%hash), "\n";

print "pass the hash as a ref: ", Dumper(\%hash), "\n";
[download]

When run, it'll look like this:

$ perl u.pl
a hash reference: $VAR1 = {
          'amountSubmitted' => 1
        };

a hash expands to a list: $VAR1 = 'amountSubmitted';
$VAR2 = 0;

pass the hash as a ref: $VAR1 = {
          'amountSubmitted' => 0
        };
[download]

So when you're going to use Dumper to display a hash, be sure to use a hash reference instead of letting the hash expand to a list of values.

You should be aware that the same thing happens with arrays: If you use Dumper on an array, you'll get $VAR=first array value, $VAR=second array value, etc., unless you use an array reference:

$ perl u.pl
array reference: $VAR1 = [
          'first value',
          'second value'
        ];

array: $VAR1 = 'first value';
$VAR2 = 'second value';

array as ref: $VAR1 = [
          'first value',
          'second value'
        ];
[download]

Update: Added bit about array/arrayref.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

What happens when you Dumper(%hash) is that %hash gets turned into a list of key/value pairs which are then passed to Data::Dumper as if you had written Dumper("key1","value1","key2","value2",...), and it then prints each individually. The best workaround is usually to write Dumper(\%hash) instead, since a reference to a hash won't get "flattened" this way.

(Update before posting: roboticus beat me to it :-) )

By the way, the code %l_pa = (%l_pa, $value); doesn't make much sense to me, but I'm not sure what its intention is because you haven't provided an SSCCE, perhaps you could do that so we can be of more help? Just a guess: perhaps you meant to dereference the hash reference with %$value?

Minor edits.

Further to what roboticus said, you can use Data::Dumper->Dump() or its faster C-coded equivalent ->Dumpxs(), which are not exported by default, to obtain a perhaps clearer output. This is more useful if inspecting multiple variables in one go.

johngg@abouriou ~/perl/Monks $ perl -Mstrict -Mwarnings -MData::Dumper
+ -E '
my %hash = ( Name => q{Fred}, Age => 28, Sex => q{M} );
print Data::Dumper->Dumpxs( [ \ %hash ], [ qw{ *hash } ] );'
%hash = (
          'Sex' => 'M',
          'Age' => 28,
          'Name' => 'Fred'
        );
[download]

I hope this is of interest.