Have you read the FAQ How can I remove duplicate elements from a list or array? If so, have you tried to modify the approaches given there to meet your individual requirements? I would modify the last example.

Try this:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my( @ordered, %grouped );

while( <DATA> ) {
    chomp;
    my @pair = split ',', $_;
    $ordered[ @ordered ] = $pair[ 0 ] unless exists $grouped{ $pair[ 0
+ ] };
    push @{ $grouped{ $pair[0] } }, $pair[1];
}
#pp \@ordered, \%grouped;

print "$_|", join ',', @{ $grouped{ $_ } } for @ordered;



__DATA__
20055111,YOUSLAV,
20055111,YURT,
20055111,TENWIMPL,
20011271,YOUSLAV,
20011271,WUMARTHE
20011541,YOUSLAV,
20011541,TENWIMPL,
20102741,WEDLOFOU,
20102741,YOUSLAV,
20102741,YURT,
20102741,KUPLYSO,
20102741,TENWIMPL,
20155505,YOUSLAV,
20155505,YURT,
20155505,TENWIMPL,
20147155,YOUSLAV,
20147155,KUPLYSO,
20147155,FRIMA,
[download]

C:\test>1215831.pl
20055111|YOUSLAV,YURT,TENWIMPL
20011271|YOUSLAV,WUMARTHE
20011541|YOUSLAV,TENWIMPL
20102741|WEDLOFOU,YOUSLAV,YURT,KUPLYSO,TENWIMPL
20155505|YOUSLAV,YURT,TENWIMPL
20147155|YOUSLAV,KUPLYSO,FRIMA
[download]

I like your code++.

A couple of minor nits:
I personally try to avoid using subscripts in favor of assigning a name to variables in a split.
In this case, I'm not sure what the number represents (or the name), I'm sure the OP knows better a better description than us.
I would use a push instead of array assignment to @ordered, just because it seems more natural to me.
This is minor stuff - no problem at all with your code.

Update: I guess I don't know what is supposed to happen if say YOUSLAV appeared twice for 20055111 or whether that is even possible to occur. If that is possible, the OP should clarify.

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my( @ordered, %grouped );

while( <DATA> ) {
    chomp;
    my ($number, $name) = split ',', $_;
    push (@ordered, $number ) unless exists $grouped{$number };
    push @{ $grouped{ $number } }, $name;
}
#pp \@ordered, \%grouped;

print "$_|", join ',', @{ $grouped{ $_ } } for @ordered;

=prints
20055111|YOUSLAV,YURT,TENWIMPL
20011271|YOUSLAV,WUMARTHE
20011541|YOUSLAV,TENWIMPL
20102741|WEDLOFOU,YOUSLAV,YURT,KUPLYSO,TENWIMPL
20155505|YOUSLAV,YURT,TENWIMPL
20147155|YOUSLAV,KUPLYSO,FRIMA
=cut

__DATA__
20055111,YOUSLAV,
20055111,YURT,
20055111,TENWIMPL,
20011271,YOUSLAV,
20011271,WUMARTHE
20011541,YOUSLAV,
20011541,TENWIMPL,
20102741,WEDLOFOU,
20102741,YOUSLAV,
20102741,YURT,
20102741,KUPLYSO,
20102741,TENWIMPL,
20155505,YOUSLAV,
20155505,YURT,
20155505,TENWIMPL,
20147155,YOUSLAV,
20147155,KUPLYSO,
20147155,FRIMA,
[download]

You said "I guess I don't know what is supposed to happen if say YOUSLAV appeared twice for 20055111 or whether that is even possible to occur" It's not possible for the term to appear twice with the number. His solution appears to work very well!

I'm very pleased to say your solution is working. I remmed out the chomp statement and put in two file handling statements and now it's doing exactly what I need. I had to install the "Data::Dump" module. Thank you, this is great work and very slick!

As you already got useful answers I propose you a short version(pay attention to windows double quotes!):

perl -F"," -lane "push @{$h{$F[0]}},$F[1]}{print map{$_.'|'.(join',',@
+{$h{$_}}).qq(\n)}keys %h" data.txt

20155505|YOUSLAV,YURT,TENWIMPL
20102741|WEDLOFOU,YOUSLAV,YURT,KUPLYSO,TENWIMPL
20011541|YOUSLAV,TENWIMPL
20011271|YOUSLAV,WUMARTHE
20147155|YOUSLAV,KUPLYSO,FRIMA
20055111|YOUSLAV,YURT,TENWIMPL
[download]

See perlrun to get all these perl switches explained, but use -MO=Deparse to see the oneliner exploded and more readable (the curly braces in $F[1]}{print are a trick called esquimo greeting;):

perl -MO=Deparse -F"," -lane "push @{$h{$F[0]}},$F[1]}{print map{$_.'|
+'.(join',',@{$h{$_}}).qq(\n)}keys %h"

BEGIN { $/ = "\n"; $\ = "\n"; }
LINE: while (defined($_ = <ARGV>)) {
    chomp $_;
    our(@F) = split(/,/, $_, 0);
    push @{$h{$F[0]};}, $F[1];
}
{
    print map({$_ . '|' . join(',', @{$h{$_};}) . "\n";} keys %h);
}
-e syntax OK
[download]

L*

perl -F"," -lane "push @{$h{$F[0]}},$F[1]}{print map{$_.'|'.(join',',@{$h{$_}}).qq(\n)}keys %h" data.txt

This definitely works too.

June 8th 2018 Discipulus added code tags

> preserve all alphabetic elements of the array but the duplicate numeric elements must be removed

but I think what you want is to parse the data pairwise ($number, $name) and have a unique list of names per number.

In this case I'd suggest building a hash of hashes (if original order doesn't matter). Just set

$names_per_num{$number}{$name} = 1

for each combination.

After that you'll just need to iterate over all numbers and print the keys of the sub-hash to get your desired output.

No code yet, we'd love to help you improving your attempts! :)

HTH!

PS: and if original order matters just use the above HoH as a %seen filter while iterating the list.

Rolf: Thank you very much for your reply! I will read the link you mentioned. I have found Perl Monks to be very helpful!

use strict;
use warnings;
use Autodie;
open my $FH, '<', 'jzelkowsz.dat';
my %data;
while (my $pair = do{ $/ = ', ';<$FH>}) {
    my ($numeric, $alpha) = split qr/,/, $pair;
    push @{$data{$numeric}}, $alpha;
}
foreach  my $num (sort keys %data) {
    $" = ',';
    $\ = "\n";
    print "$num|@{$data{$num}}";
}
[download]

Thank you, Bill. I appreciate a different way of looking at the problem.