Better solution:

my %seen;
my @uniqWebCustomers = grep !$seen{$_}++, @webCustomers;
[download]

Better yet:

use List::Util qw( uniq );

my @uniqWebCustomers = uniq @webCustomers;
[download]

I agree with the "Better yet," but in situations where I do something like option 1, I like to wrap it in a do block to maintain tight scoping:

my @uniqWebCustomers = do{
    my %seen;
    grep !$seen{$_}++, @webCustomers;
};
[download]

---

#11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

If you're going to add a block, make it a sub.

sub uniq { my %seen; grep !$seen{$_}++, @_ }

my @uniqWebCustomers = uniq @webCustomers;
[download]

@tempCustArray = keys %{+ map { $_ => 1 } @webCustomers };
[download]

Update 2: This works:

my @t = keys %{+{ +map { $_ => 1 } qw|uno dos tres| }}
[download]

Update 3: The "+" signs are unnecessary .. this works:

@tempCustArray = keys %{{ map { $_ => 1 } @webCustomers }}
[download]

it seems to be a question of why the extra braces are required.

The outer %{ ... } is a hash dereference.

The inner { ... } creates a hash and returns a reference to it.

In your first snippet, you have a hash dereference, but no hash.

Thanks for the clarification, ikegami (++).

The postfix syntax below also works, and is easier to read.

my @t = keys {map { $_ => 1 } qw|uno dos tres| }->%*;
[download]

                Memory fault   --   brain fried

WOW, that worked like a champ! Thank you so much!