If you're dealing with log files, they're often large and copying all their data into arrays, and then creating more arrays from that data, is generally not a good idea: it's likely to be very slow and you could run into memory issues.

Instead, read the files one line at a time or, in your case here, one paragraph at a time. The following line (which you'll see in the script I've provided below) turns on paragraph mode:

local $/ = '';
[download]

I'll also just comment on all those do statements. Is there a reason you coded it that way? Instead of

do { STATEMENTS } if CONDITION;
[download]

why not write

if (CONDITION) {
    STATEMENTS
}
[download]

Anyway, I truncated your data quite substantially but left the main features: head, multiline data and tail. The data you posted had a space after every "Receive:" — I've left that in but you should check if it's there in the original data (it could be an artefact of copy/paste, HTML rendering, etc.). Here's the script to process it:

#!/usr/bin/env perl

use strict;
use warnings;

{
    local $/ = '';
    my $wanted = "Receive: \n";
    my $re = qr{(\[\d\d\]|.)};

    while (<DATA>) {
        chomp;
        next unless substr($_, 0, length $wanted, '') eq $wanted;
        #print "|$_|\n";  # For demo only - see current $_ value
        my @hex;

        while (/$re/g) {
            push @hex, length $1 == 1
                       ? sprintf '%02X', ord $1
                       : substr($1, 1, 2);
        }

        print "@hex\n";
    }
}

__DATA__
Message:
11 started at: 2018-06-29 16:20:07

Transmit: 
ATV1[0D]


Transmit: 
[01]10179311000=[03]

Receive: 
[01]20179321157>[02]00
00
00[03][00]

Transmit: 
[01]10179312000>[03]

Receive: 
[01]20179331157?[02]00
00
00[03][00]

Message:
amount of bytes collected ok, data accepted 

Message:
11 ended at: 2018-06-29 16:20:46
[download]

Output:

01 32 30 31 37 39 33 32 31 31 35 37 3E 02 30 30 30 30 30 30 03 00
01 32 30 31 37 39 33 33 31 31 35 37 3F 02 30 30 30 30 30 30 03 00
[download]

If you uncomment that demo print line, you'll probably find it a bit easier to compare the data being processed and the data being output. It changes the output to this:

|[01]20179321157>[02]00
00
00[03][00]|
01 32 30 31 37 39 33 32 31 31 35 37 3E 02 30 30 30 30 30 30 03 00
|[01]20179331157?[02]00
00
00[03][00]|
01 32 30 31 37 39 33 33 31 31 35 37 3F 02 30 30 30 30 30 30 03 00
[download]

Thanks kcott!

The reason I prefer map/grep than a while to deal with something like this is because I like the feel that map/grep bring me. Image you drive on a freeway, if the way is only one exit, you can concentrate driving or you have to note every road board. the performance you sacrificed is worthy I think. ;)

Some might disagree with you regarding the clarity of the grep and map approach and a solution using loops of various flavours might be easier to maintain in the long run. However, here's a solution for you which wraps everything in a do block to contain the localization of paragraph mode.

use 5.022;
use warnings;

open my $logFH, q{<}, \ <<__EOD__ or die $!;
Message:
11 started at: 2018-06-29 16:20:07

Transmit: 
ATV1[0D]


Transmit: 
[01]10179311000=[03]

Receive: 
[01]20179321157>[02]00000068801400000000000000000000000000000000006880
+14000000
0000000068801400000000000000000000400000000040000000004000000000400000
+00000000
000000000000000000[03][00]

Transmit: 
[01]10179312000>[03]

Receive: 
[01]20179331157?[02]00000068801400000000000000000000000000000000006880
+14000000
0000000068801400000000000000000000400000000040000000004000000000400000
+00000000
000000000000000000[03][00]

Transmit: 
[01]10179313000?[03]

Receive: 
[01]201793411578[02]00000068801400000000000000000000000000000000006880
+14000000
0000000068801400000000000000000000400000000040000000004000000000400000
+00000000
000000000000000000[03][00]

Transmit: 
[01]101793140008[03]

Receive: 
[01]201793511579[02]00000068801400000000000000000000000000000000006880
+14000000
0000000068801400000000000000000000400000000040000000004000000000400000
+00000000
000000000000000000[03][00]

Transmit: 
[01]101793150009[03]

Receive: 
[01]001793611578[02]00000068801400000000000000000000000000000000006880
+14000000
0000000068801400000000000000000000400000000040000000004000000000400000
+00000000
000000000000000000[03][00]



Message:
reading of spontaneous buffer not ordered

Message:
Periodic Buffer: Start: 2018-06-29 13:15:00 End: 2018-06-29 16:10:00
Periods: 36  Dec: 8  Points: 15  bytes collected: 5564  estimated: 556
+4

Message:
amount of bytes collected ok, data accepted 

Message:
11 ended at: 2018-06-29 16:20:46
__EOD__

my @records = do {
    local $/ = q{};
    map  {
        join q{ },
           map {
               m{\[\d\d\]}
               ? substr $_, 1, 2
               : map { sprintf q{%02x}, ord } split m{};
           } @$_;
    }
    map  {
        s{^Receive:}{};
        s{\s+}{}g;
        [ split m{(\[\d\d\])} ];
    }
    grep { m{^Receive:} }
    <$logFH>;
    };

say qq{$_\n} for @records;
[download]

I don't show the output here as it will wrap horribly. Despite giving you this solution I would recommend sticking with looping constructs.

Update: Got rid of the middle map by moving the split into the first map.

Update 2: The first update would have made more sense if I'd included the original code so here it is :-

    map  {
        join q{ },
           map {
               m{\[\d\d\]}
               ? substr $_, 1, 2
               : map { sprintf q{%02x}, ord } split m{};
           } @$_;
    }
    map  { [ split m{(\[\d\d\])} ] }
    map  {
        s{^Receive:}{};
        s{\s+}{}g;
        $_;
    }
    grep { m{^Receive:} }
    <$logFH>;
[download]

Many thanks johngg !

although you recommend loop way to deal with something like this, I prefer map/grep way. It's like a FIFO queue, so that you can easily understand how original data transform to the data I want.