#!/usr/bin/env perl
use warnings;
use strict;
use feature qw{ say };

use List::PowerSet qw{ powerset };

my %groups;

while (<DATA>) {
    my @numbers = split;
    for my $ps (@{ powerset(@numbers) }) {
        next if @$ps < 2;
        $groups{"@$ps"}++;
    }
}

for my $group (keys %groups) {
    next if $groups{$group} == 1;
    say "$group repeated $groups{$group} times";
}

__DATA__
1 2 5 9
1 2 5 10
4 5 10 12
5 9 10 11
[download]

Output:

5 9 repeated 2 times
1 2 repeated 2 times
1 5 repeated 2 times
5 10 repeated 3 times
1 2 5 repeated 2 times
2 5 repeated 2 times
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

It is unclear where you are having problems. Is it:

1. You have code which runs but doesn't do what you want - in which case, show your code.
2. You have code which doesn't run - in which case, show your code and the precise text of the error message.
3. You have an algorithm but are having trouble turning it into code - in which case, show your algorithm.
4. You have no algorithm.

Thank you for reply. I dont have code. I'm learning Perl and was able to count no of times a digit repeated in file , and now trying to do group (:D.

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1218823

use strict;
use warnings;

my %dups;

local $_ = do { local $/; <DATA> };

/\b(\d+)\b.*?\b(\d+)\b(?{$dups{"$1 $2"}++})(*FAIL)/;

$dups{$_} > 1 and print "$_ repeated $dups{$_} times\n" for sort keys 
+%dups;

__DATA__
1 2 5 9
1 2 5 10
4 5 10 12
5 9 10 11
[download]

Outputs:

1 2 repeated 2 times
1 5 repeated 2 times
2 5 repeated 2 times
5 10 repeated 3 times
5 9 repeated 2 times
[download]

What you need to do is called 'software development', and it consists of two steps:

1. Develop the logic to solve the problem you are facing; and
2. Write software that replicates the logic you've developed.

Assuming "repeated number groups" rather than pairs, and without modules so you can see the logic:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my %dups;

while( <DATA> ) {
    my @nums = split ' ', $_;
    for my $l ( 2 .. @nums ) {
        ++$dups{ join ' ', @nums[ $_ .. $_+$l-1 ] } for 0 .. @nums - $
+l;
    }
}
#pp \%dups;

$dups{ $_ } > 1 and print "$dups{ $_ } x '$_'" for sort keys %dups;

__DATA__
1 2 5 9
1 2 5 10
4 5 10 12
5 9 10 11
[download]

Produces:

C:\test>1218823.pl
2 x '1 2'
2 x '1 2 5'
2 x '2 5'
2 x '5 10'
2 x '5 9'
[download]

looks like 12 repates 3 times.

Thank you. 12 is not '1 2'. I want to know how many times the same pattern ( group ) is repeated.

1 2 5 9

1 2 5 10

4 5 10 12

5 9 10 11

output:-

1 2 repated 2 times

2 5 repeated 2 times

5 10 repeated 3 times

5 9 repated 2 times

Thanks