Here's a solution that doesn't depend on the order of the lines. It finds all the titles using a regex and counts them using a hash, and then selects the one that appears exactly once, warning or dieing if there isn't exactly one. You haven't specified a few things about the title: line, like whether there can be #'s in the titles, and what kind of text might appear after the closing #.

use warnings;
use strict;

my %mycorpus = (
    a => "<blah blah blah 
blah
title:#this is text I want 1#
blah blah blah",

    b => "blah
title:#this is text I do not want#
title:#this is text I want 2#
blah
title:#this is text I do not want#
blah",

    c => "blah blah
title:#this is text I do not want#
title:#this is text I want 3#
title:#this is text I do not want#
title:#this is text I do not want#
blah",
);

for my $filename (sort keys %mycorpus) {
    my %titles;
    $titles{$1}++
        while $mycorpus{$filename} =~ m{ ^ title:\# (.*) \# }xmg;
    my @once = grep { $titles{$_}==1 } sort keys %titles;
    die "No title found in $filename" unless @once;
    warn "More than one title found in $filename" if @once>1;
    my $title = $once[0];
    print "$title\n";
}

__END__

this is text I want 1
this is text I want 2
this is text I want 3
[download]

Brilliant, thank you very much! (Also, thanks for including examples of how to implement "die" and "warn": I rarely use these signals myself, but having just run your code on my data, it allowed me to identify a major error in the formatting of some of the data that would have caused a major headache later!).

How about this loop?

foreach my $filename (sort keys %mycorpus) {
  my $titles = '';
  my $counter = 0;
    while ($mycorpus{$filename} =~ /title:#(.*?)#\s*$/gm){
      if($counter++){
        last if $counter++; # skip the rest of the matches
        # can also be used to print warnings about multiple titles
        # and check $1 against $titles if they are the same, or not
      }else{
        $titles = $1; # first match, we can store it,
        print  "$titles \n"; # or print it out
      }
      
  }
}
[download]

the output is

this is text I want 1 
this is text I want 2 
this is text I want 3
[download]

You can also replace the while with an if, and then it just matches the first title# .

foreach my $filename (sort keys %mycorpus) {
  my $titles = '';
    if ($mycorpus{$filename} =~ /title:#(.*?)#\s*$/m){
      $titles = $1;
      print  "$titles \n";    
  }
}
[download]

The output is the same. I think you wanted the multiline regexp modifier to match a newline inside your filedump string.

edit: better structure to allow more post-work (commented what can be done there). Did also remove the /g (go) modifier in the "if" example as it is not needed there.

This works perfectly! Thank you very much for your help/time. I feel a bit daft after seeing how (relatively) simple the solution actually was, but I've learned a lot from your code here. Thanks! EDIT: Ah, thanks for the reworking! It was probably my sleep-drived incoherant question that caused the confusion! Thanks again.

Note that FreeBeerReekingMonk's solution only works because it relies on the blah on the line "title:#this is text I do not want# blah", and it only grabs the first title:. If I remove the blah or reorder the lines in the third example, it does not work.

This is essentially the same approach haukex uses, but with some different features:

• Titles are normalized before being added to the  %titles duplication detection hash according to their normalized form. This means that, in this implementation,
      'This is a title'
  and
      'This  IS   A   Title'
  are the same for the purpose of rejecting duplicate titles. This may or may not be what Maire wants; it's just an example of what's possible. The extent of normalization is easily adjusted.
• Titles are allowed to wrap from one line to the next. This applies to both unique and duplicate titles. Again, Maire may not want this, and it's easily turned off.
• A title may not be the only thing on a line. Another thing that's easy to change.
• A  '*' is used in place of the original  '#' character to delimit titles. This is done only to demonstrate that any character, even a regex metacharacter, could be used as a delimiter. (It wouldn't be that hard to change the regexes to accommodate multi-character delimiter sequences.)

c:\@Work\Perl\monks\Maire>perl remove_dup_lines_1.pl
a: 'this is text I want 1'
b: 'this is text I want one'
c: 'this is text I want A'
c: 'this is text
I want over multiple lines B'
c: 'this is text I want C'
[download]

Thank you very much for this (and also for your very clear explanations!).

#!/usr/bin/perl
use strict;
use warnings;

my %mycorpus = (
    a => "<blah blah blah 
blah
title:#this is text I want 1#
blah blah blah",

    b => "blah
title:#this is text I do not want# blah
title:#this is text I want 2#
blah
title:#this is text I do not want#
blah",

    c => "blah blah
title:#this is text I want 3#
title:#this is text I do not want#
title:#this is text I do not want#
title:#this is text I do not want#
blah",
);


foreach my $filename (sort keys %mycorpus) 
{
   foreach my $line (split /\n/,$mycorpus{$filename})
   {
       if ($line =~ /^title:#(.*)#\s*$/)
       {
           print "$line\n";
           last;
       }
   }
}

__END__
title:#this is text I want 1#
title:#this is text I want 2#
title:#this is text I want 3#
[download]

Thank you!