use feature 'refaliasing';
no warnings 'experimental';

my ($x, $y, %h);
\$h{foo} = \$x;
\$y = \$h{foo};
$x = 99;
printf "%d %d %d\n", $x, $y, $h{foo}; # prints 99 99 99
[download]

Buts it's of course still an experimental feature.

Dave.

cool thanks! :)

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

To answer my own question: Yes!

use strict;
use warnings;
use 5.10.0;


package Tie::Alias;
require Tie::Scalar;
our @ISA = qw(Tie::Scalar);
use Data::Dump qw/pp dd/;





sub FETCH {
    #pp \@_;
    my $obj =shift;
    return ${$obj->{alias}};
}

sub STORE {
    #pp \@_;
    my $obj = shift;
    ${$obj->{alias}} = $_[0];
}

sub TIESCALAR {
    #pp \@_;

    my $class = shift;
    my $alias = \ shift;

    my $obj = bless {alias => $alias}, $class;
    return $obj;
}




package main;

my $h={};

my $y;

tie $h->{y},'Tie::Alias', $y;

$y=666;

say $h->{y};

$y=42;

say $h->{y};

$h->{y}=123;

say $y;

my $g={};

tie $g->{y},'Tie::Alias', $y;

say $g->{y};

$h->{y}=999;

say "$h->{y},$g->{y},$y";

$h->{x}="whatever";

say "$h->{x},$g->{x}";
[download]

Use of uninitialized value in concatenation (.) or string at d:/Users/
+lanx/exp/tie_alias.pl line 72.
666
42
123
123
999,999,999
whatever,
[download]

I managed to alias a scalar to one hash-element.

But can I alias hash-elements from different hashes to the same scalar?

i.e. when I change $x it mirrors in $h{x} and $g{x} and vice versa?

I'm not really sure that Perl syntax allows you to alias hash entry scalars, but you can achieve the effect by using Data::Alias:

use Data::Alias;
use feature 'say';
$baz{'buf'} = 'Hello';
alias $foo{'bar'} = $baz{'buf'};
say $foo{'bar'};
$foo{'bar'} = 'World';
say $baz{'buf'};
$baz{'new'} = 'old';
say $foo{'old'};

__END__
Hello
World
Use of uninitialized value in say at ...
[download]

Thanks.

Background: I was thinking to emulate the Python OO system, and in that language a class attribute can be accessed thru the same mechanism like an instance attribute.

Hence assigning self.class_attr will change the value for all objects, assigning to self.obj_attr only to that specific object.

Data::Alias seems like a good idea, unless Python has optional magic __hooks__ to intercept a get/set on class_attr.

In that case I should rather use Tie::Scalar.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}