Please try either

• 'singlequotes'
• the q{uote-operator} with arbitrary delimiter (pairs)
• <<'__here_docs__' surrounded by single-quotes.

see non-interpolating commands listed in perlop#Quote-and-Quote-like-Operators for further information.

HTH! :)

update

> get perl to see the awk script as just words

in case you explicitly need words, see also qw/quoted words/ which returns a list of strings.

this is awesome! worked like a charm :)

Could you show a Short, Self-Contained, Correct Example, that is, a short piece of example code that shows the problem, with short sample input and the expected output you want to get, and the actual output, including any error messages, each inside <code> tags?

Going off of your description, I would recommend a module like IPC::System::Simple, its systemx and capturex functions avoid the shell*, and as LanX said, you can provide the commands to be executed in Perl constructs like q{}. Note how in the following, I don't have to escape quotes or $ (it's printing the $$ variable).

use warnings;
use strict;
use IPC::System::Simple qw/systemx capturex/;
  
systemx('perl', '-e', q{print "'$$'\n"} );
my $o = capturex('perl', '-e', q{print "'$$'"} );
print "<$o>\n";
[download]

I wrote at length about the issues with running external commands here.

* Update: Note this also means there won't be any shell redirections or piping available. If you need this, please show and example of the commands you're trying to run, often there is a way to work around it e.g. with capturex, temporary files, or a different module like IPC::Run3 or IPC::Run.

G'day Blur,

Welcome to the Monastery.

Here's a pipeline containing awk:

$ echo "a b c" | awk '{print $2}'
b
[download]

Here's a Perl script containing that pipeline. Note that only the '$' needed to be escaped (\$2):

$ cat pm_1223868_heredoc_awk.pl
#!/usr/bin/env perl

use strict;
use warnings;

print <<`EOS`;
echo "a b c" | awk '{print \$2}'
EOS
[download]

It produces the same output:

$ pm_1223868_heredoc_awk.pl
b
[download]

Look at perlop - Quote-Like Operators - <<EOF and scroll down to the Backticks entry for more about this type of heredoc in Perl.

[I see others have already mentioned the lack of information and, as this is your first post, I won't go on about it; however, you will need to show us an example with the problem symbols for us to help you further.]

If you don't want to rewrite the awk code manually, you could still try to translate it automatically with the a2p (awk to Perl) utility: see a2p for details.

After posting the heredoc with backticks solution, I thought of another way that required no escaping.

$ cat pm_1223868_heredoc_awk_2.pl
#!/usr/bin/env perl

use strict;
use warnings;

open my $fh, '-|', q[echo "a b c" | awk '{print $2}'];
print <$fh>;
[download]

$ pm_1223868_heredoc_awk_2.pl
b
[download]

That's just the guts of the solution. You'll need to add error handling at least. See open for more about this.