Maybe what you are after is somewhat like this:

use strict;

{ # just a block
    my $test; # the lexical one
    sub foo {
        print "In foo: \$test=$test\n";
        $test = "Hello world";
        print "In foo: \$test=$test\n";
    }
    sub bar {
        print "In bar \$test=$test\n";
    }
}

my $test; # the global one

print "Global \$test=$test\n";

foo();
print "Global \$test=$test\n";
bar();
print "Global \$test=$test\n";
[download]

The two functions are defined in a block and therefore share the lexical (please do not use the term local in Perl) variables declared within that block ABOVE the functions.

> The two functions are defined in a block and therefore share the lexical

Additional note: this is a fine example for using Closures.

The two functions are "closing" over the lexical variable $test.

And this $test has a lexical (i.e. static) scope restricted to the block.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

PS: it also demonstrates that closure don't need to be anonymous. There is a widespread misconception in some other languages that "closure" is a synonym for "anonymous function".

You want the same variable to hold two different values in the same scope. That won't work.

Unless you do something weird like use dualvar and evaluate in number or string context to force one or another value to be used.

use strict;
use warnings;
no warnings 'uninitialized';

## not recommended
use Scalar::Util 'dualvar';

my ($test, $test2);

print sprintf('1: %s', $test), "\n";

if (not defined $test) {
    $test = dualvar(0, 'OK');
    print sprintf('2: %s', $test), "\n";
}

print sprintf('3: %s', $test > 1 ? $test : undef), "\n";

if (not defined $test2) {
    print sprintf('4: %s', $test), "\n";
}

__END__
[download]

Hope this helps!

 
use strict;
use warnings;

my ($test,$test2,$test3);       # parens needed for my(LIST)

print "$test\n"; 
## print nothing

if(not defined $test){
    $test3 = "GOOD";            # no my, no private but upper scope
    print "$test3\n"
} 
## print GOOD 

print "$test\n"; 
## print nothing


if (not defined $test2) {
    print "$test3\n";           # print $test3 from upper scope
}
## print GOOD. GOOD is defined on first "if" function.
[download]

RESULT:

Use of uninitialized value $test in concatenation (.) or string at d:/
+tmp/pm/my.pl line 8.
Use of uninitialized value $test in concatenation (.) or string at d:/
+tmp/pm/my.pl line 15.

GOOD

GOOD
[download]

I have absolutely no clue about what exactly you are trying to achieve, but maybe it helps you to point out that "my"-variables are lexically scoped and that means that they are only visible within the nearest "{"-block.

And if you stack my-declarations you simply shadow previous ones.

Consider this:

use strict;

my $whatever = "outer";

if (1) {
 my $whatever = "inner";
 print "$whatever\n";
}
print "$whatever\n";
[download]

Within the if-block $whatever is changed to "inner", and that is what is printed from the print there, but once you leave this scope you refer to the outer definition and so the outer print prints "outer" (what else?).

In your case you have "my $test" in the outer scope.

Then you introduce a new scope with "if" and declare a new variable with "my $test" and set that to "GOOD". Here you shadow the already introduced variable. Later (in another if-scope) you introduce yet another variable (again shadowing the outer one) and that of course knows nothing about the assignment you did in another scope.

Short story:

You are dealing with three different variables here: The outer $test, the $test in the first if and the $test in the second if.

This probably was confusing - sorry for that but I am a bit drunk...