you can have exotic utf8 values without use utf8;, but not variable names.

# Dumper prints character codes for wide characters
$ perl -MData::Dumper -Mutf8 -E'print Dumper "привет"'
$VAR1 = "\x{43f}\x{440}\x{438}\x{432}\x{435}\x{442}";
# Dumper prints bytes, and I get exactly what I'd typed
$ perl -MData::Dumper -E'print Dumper "привет"'
$VAR1 = 'привет';
# byte-string consists of 12 bytes of UTF-8
$ perl -MData::Dumper -E'say length "привет"'
12
# character-string consists of 6 wide characters
$ perl -MData::Dumper -Mutf8 -E'say length "привет"'
6

Every subsequent time, it fails, and $! is stone silent.

The functionality I would like to add are conditions such that if a translate call hangs, I can get to the next one, so what I'm fishing for is code that would go the next in the for loop if it lasts for, say, a minute.

Thanks for elaborating on utf8 and suggesting on a way forward with my questions. As is frequently the case, the monastery has another thread going to discuss the same issue: Can we write multi-threaded scripts ?. I looked at the reference that localshop posted and found code that uses perl's native language to thread. I would prefer not to have to use a module just for this little task. I must say, however that I fall short on my first attempt in some ways. Output then source:

$ ./2.fork.pl 
this is task 1 with pid 0
Waiting for child processes..
this is task 2 with pid 0
this is task 3 with pid 0
44
bing's translation is 
unctuous hypocrisy flowing from the tube

елейным лицемерие течет из трубки

 English -> Русский 
Child with PID=23085 finished..
43
42
41
slept 5
40
39
38
ERROR Oops! Something went wrong and I can't translate it for you :(
yandex's translation is 
Child with PID=23086 finished..
37
36
slept 10
35
google's translation is 
unctuous hypocrisy flowing from the tube

неприступное лицемерие, вытекающее из трубки
(nepristupnoye litsemeriye, vytekayushcheye iz trubki)

Translations of unctuous hypocrisy flowing from the tube
 English -> Русский 

unctuous hypocrisy flowing from the tube
    неприступное лицемерие, вытекающее из трубки, елейное лицемерие течет из трубки
Child with PID=23087 finished..
Done.
$ cat 2.fork.pl 
#!/usr/bin/perl -w
use 5.011;

my $string = "unctuous hypocrisy flowing from the tube";

my $pid1 = fork();
if ( $pid1 == 0 ) {    # Task 1
    say "this is task 1 with pid $pid1";
    my $command = "trans :ru -e bing \"$string\" >1.bing.txt"; 
    system("$command");
    say "bing's translation is ";
    system("cat 1.bing.txt");
    exit 0;
}

my $pid2 = fork();
if ( $pid2 == 0 ) {    # Task 2
    say "this is task 2 with pid $pid2";
    sleep 5;
    say "slept 5";
    system("trans :ru -e yandex \"$string\" >1.yandex.txt");
    say "yandex's translation is ";
    system("cat 1.yandex.txt");
    exit 0;
}

my $pid3 = fork();
if ( $pid3 == 0 ) {    # Task 3
    say "this is task 3 with pid $pid3";
    sleep 10;
    say "slept 10";
    system("trans :ru -e google \"$string\" >1.google.txt");
    say "google's translation is ";
    system("cat 1.google.txt");
    exit 0;
}

say "Waiting for child processes..";
my $counter = 45;
local $SIG{ALRM} = sub {
    say --$counter;
    alarm 1;
};
alarm 1;

while ((my $pid = wait) != -1) {
    say "Child with PID=$pid finished..";
}

alarm 0;
say "Done.";
__END__

Even with all the say statements dropped in, I find execution hard to follow. I'm baffled that pid's are zero within a block, but not so when they finish. What alarm truly does here is unclear. Finally, there is no code to kill pid's when the timer reaches zero.

I'm also fishing for code that would do this within the following loop:

  print "Get other translations(y/n)?: ";
  my $prompt = <STDIN>;
  chomp $prompt;
  if ( $prompt eq ( "y" | "Y" ) ) {
    my @translators = qw /yandex bing/;
    for my $remote (@translators) {
      my $trans_munge = path( $vars{translations}, "$remote." . $munge
+ );

      ## use trans shell
      say "getting translation from $remote";
      system("trans :$lang -e $remote file://$in_path >$trans_munge");
    }
[download]

Again, thanks for the very helpful comments.

I'm baffled that pid's are zero within a block, but not so when they finish.

fork causes the execution of a process to split into two different processes, sharing the initial memory layout but not the following changes to the variables. To help the program discern which of the two it has become, the newly produced ("child") process receives 0 as the return value of fork() and the old one ("parent") gets returned the PID of the new process. This is why you had to put an exit 0; at the end of the if ($pid == 0) block: otherwise both the parent and the child would continue executing the same parts of the program, causing a lot of confusion.

wait returns the real (former) PIDs of the freshly terminated child processes. If the child wanted for some reason to know its PID, it could have used the $$ variable.

This example might help:

if (fork() == 0) {
 system("sh", "-c", "sleep 3 # getting yandex translation");
 exit(0);
}
if (fork() == 0) {
 system("sh", "-c", "sleep 2; # getting google translation");
 exit(0);
}

system("pstree -Apal $$"); # pstree gets the PID of the parent process
+ as its argument

while((my $pid = wait()) != -1) {
 say "$pid terminated"
}
__END__
perl,29173 test.pl
  |-perl,29174 test.pl
  |   `-sh,29177 -c sleep 3 # getting yandex translation
  |       `-sleep,29179 3
  |-perl,29175 test.pl
  |   `-sh,29178 -c sleep 2; # getting google translation
  `-pstree,29176 -Apal 29173
29175 terminated
29174 terminated
[download]

pstree command draws all child processes of the main Perl process (including itself) with their command line arguments. The Perl processes having the same command line arguments but different PIDs are the copies created by fork().

What alarm truly does here is unclear. Finally, there is no code to kill pid's when the timer reaches zero.

alarm arranges for a SIGALRM signal to be delivered to the calling process in the number of seconds specified as its argument. It behaves as if something else kills the process which had called alarm and forgot to disarm it. The good part is that one can use $SIG{ALRM} to trap the signal and do something meaningful instead of dying, but in your case the work is already being done in a child process, and we can let it be killed:

my $start = time;

if (fork() == 0) {
 # arm the alarm clock
 alarm(10);
 # create a child process that sleeps
 system("sleep 365d");
 exit(0);
}

system("pstree -Apal $$");

while((my $pid = wait()) != -1) {
 say "$pid terminated"
}

say time-$start, " seconds elapsed instead of a year"
__END__
perl,29620
  |-perl,29621
  |   `-sleep,29623 365d
  `-pstree,29622 -Apal 29620
29621 terminated
10 seconds elapsed instead of a year
[download]

Aldebaran:

Regarding part of your your question "I'm looking for a way to make the failure of mkdir more informative for the case that the directory already exists. I keep the mkdir line so that it will work the first time it is used. Every subsequent time, it fails, and $! is stone silent.", I'd suggest creating a function that checks whether the directory exists before creating it, something like (untested):

sub createDir {
    my $dirName = shift;
    if (-e $dirName) {
        if (-d $dirName) {
            return "Directory $dirName already exists!";
        }
        else {
            return "Can't create $dirName because there's a file in th
+e way!";
        }
    }
    mkdir $dirName or return $!;
}
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

I'd suggest creating a function that checks whether the directory exists before creating it

sub createDir {
    my $dirName = shift;
    if (-e $dirName) {
        if (-d $dirName) {
            return "Directory $dirName already exists!";
        }
        else {
            return "Can't create $dirName because there's a file in th
+e way!";
        }
    }
    mkdir $dirName or return $!;
}
[download]

No. Just no. Or in more words: TOCTTOU.

The only sane way to do this is to run mkdir and have it fail in case the target already exists. This way, the operating system guarantees that there won't be a race.

mkdir $path or die "Can't mkdir $path: $!";
[download]

It will fail with EEXISTS at least on Unix and Windows if the target already exists. There are several more possible errors, e.g. lack of permissions, filesystem problems. See POSIX.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

Thx for your response, alexander, I rewrote the function to reflect $sftp->error as a first best way to get useful error info from Net::SFTP::Foreign. As I started to test the new create directory, I did discover that having a plain file as the directory one wants to create causes an error, but I have played enough with this race condition that I don't want to play anymore. I'm reminded of John van Neumann's adage: "Don't play bad logic games."

I also made a first attempt at handling the error. One is left to ponder how an sftp method call to mkdir might fail and what a person with perl can do about it. It's common for the wireless to give out, as the laptop roams with me at tortoise speed. It's a hard thing to try to induce at a critical moment against the swiftness of machine instructions.

I'm going to revert to an architecture where I deal with the consequences of the mkdir as the critical path. I tried to write a code to remove the file, and wanted to try to do some other things if I lose my sftp connection. It's a big mess. I also tried to limit processes to reasonable amounts of time, but I haven't figured out how to handle $SIG{ALRM} yet, as none of these processes terminates. I'm gonna put abridged output and then source between readmore tags and pull out a couple issues.

Read more... (5 kB)

Let me just ask: do people ping anymore, or is that an old-fashioned way to see if one has internet connectivity? For example, I pinged perlmonks and got no answer, and had my terminal tied up. Might a person use curl instead?

What would I have to add for any of those alarms to terminate the process in which they are set?

Thanks all for comments

Thx roboticus, people might have different needs for their mkdir capability. Given that I'm the only person running this script, I don't see how this can create a race condition.

  #load html file to server
  my $server_dir = $vars{"server_dir"};
  say "server dir is $server_dir";
  my $return1 = createDir( $server_dir, $sftp );
  say "return1 is $return1";
  $sftp->setcwd("/$server_dir")  or warn "setcwd1 failed $!\n";
  $sftp->put( $vars{html_file} ) or die "html put failed $!\n";

  #load css file to server
  $sftp->setcwd("/css") or warn "setcwd2 failed $@\n";
  my $path3 = path( $vars{css_path}, $vars{"css_file"} );
  say "path3 is $path3";
  my $remote_css = $vars{"css_file"};
  $sftp->put( "$path3", $remote_css ) or warn "css put failed $@\n";

  # upload images
  my $image_dir = $vars{"image_dir"};
  say "image dir is $image_dir";
  my $return2 = createDir( $image_dir, $sftp );
  say "return2 is $return2";
  $sftp->setcwd("/$image_dir") or warn "setcwd2 failed $!\n";
  my $return3 = createDir( $vars{remote_dir}, $sftp );
  say "return3 is $return3";
  $sftp->setcwd( $vars{remote_dir} ) or warn "setcwd3 failed $!\n";
  print $sftp->cwd(), "\n";
[download]

I had to make the logic work for Net::SFTP::Foreign:

sub createDir {
  use 5.011;
  use Net::SFTP::Foreign;
  my ( $dirName, $sftp ) = @_;
  if ( $sftp->test_e($dirName)) {
    if (  $sftp->test_d($dirName)) {
      say "execution was here";
      return "Directory $dirName already exists!";
    }
    else {
      return "Can't create $dirName because there's a file in the way!
+";
    }
  }
  my $success = $sftp->mkdir($dirName) or return $!;
  return $success;
}
[download]

Output:

Put file to server(y/n)?: y
server dir is perlmonks
execution was here
return1 is Directory perlmonks already exists!
path3 is /home/bob/2.scripts/pages/1.timeout/template_stuff/1.timeout1
+.css
image dir is pmimage
execution was here
return2 is Directory pmimage already exists!
return3 is 1
/pmimage/1.timeout6
[download]

I think that's got it. Thank you.

$sftp->mkdir("/$server_dir")   or warn "mkdir1 failed $!\n";
$sftp->mkdir("/$image_dir")        or warn "mkdir2 failed $!\n";
[download]

Now for the questions. I'm looking for a way to make the failure of mkdir more informative for the case that the directory already exists. I keep the mkdir line so that it will work the first time it is used. Every subsequent time, it fails, and $! is stone silent. This module is on github at html7.pm.

The mkdir you are using here is not the build-in mkdir. The latter sets $! on error (and perhaps $^E). The former one is a method of some SFTP object that could do the same, but probably has a different error mechanism.

The code on github currently uses Net::SFTP::Foreign, and as already explained, it requires to check $sftp->error() instead of $!. You could also get rid of manual error checking by using autodie mode, much like in DBI.

Alexander