in reply to Re: Copy an hash modifying some selected values
in thread Copy an hash modifying some selected values

Thank you! The result for the code: 
use strict;
use Data::Dumper;

my %hash1 = (
        key1 => 'relative_path',
        key2 => {
                key21 => 'another_relative_path',
                key22 => '/an_absolute_path',
                key23 => 'relative_path',
        },
        key3 => '',
        key4 => 4
);

my @paths = ('key1', 'key2:key22', 'key2:key23');

for my $path (@paths) {
   my @path = split(/:/, $path);
   my $val = dive(\%hash1, @path);
   warn $val;
}

sub dive {
   my $r = shift;
   $r = $r->{shift(@_)} while $r && @_;
   return $r;
}

[download]
is: 
relative_path at test2.pl line 20.
/an_absolute_path at test2.pl line 20.
relative_path at test2.pl line 20.

[download]
So I can get the values of interest to be checked, but how do I set them in the new %hash2?

Replies are listed 'Best First'.
Re^3: Copy an hash modifying some selected values
by ikegami (Patriarch) on Nov 07, 2018 at 19:24 UTC

    Did you look at the module I mentioned? 

    use Data::Diver qw( DiveVal );

my @paths = ('key1', 'key2:key22', 'key2:key23');

for my $path (@paths) {
   my @path = split(/:/, $path);
   my $new_val = ...;
   DiveVal(\%hash, map \$_, @path) = $new_val;
}

    [download]

    or 

    sub dive_val :lvalue {
   my $p = \shift;
   $p = \( $$p->{$_} ) for @_;
   $$p
}

my @paths = ('key1', 'key2:key22', 'key2:key23');

for my $path (@paths) {
   my @path = split(/:/, $path);
   my $new_val = ...;
   dive_val(\%hash, @path) = $new_val;
}

    [download]
[reply]
[d/l]
[select]
      Thank you!
      I still get an error with your version of the routine so I will use Data::Diver.
      I would prefer your routine since it is pure Perl... just in case you would want to fix my example below. 
      use strict;
use Data::Dumper;
use Data::Diver qw( DiveVal );
use Storable 'dclone';

my %hash1 = (
        key1 => 'relative_path',
        key2 => {
                key21 => 'another_relative_path',
                key22 => '/an_absolute_path',
                key23 => 'relative_path',
        },
        key3 => '',
        key4 => 4
);

my $hash2 = dclone \%hash1;
my $hash3 = dclone \%hash1;
my $home = '/home';

my @paths = ('key1', 'key2:key22', 'key2:key23');

for my $path (@paths) {
   my @path = split(/:/, $path);
   my $val = dive(\%hash1, @path);
   my $new_val = (substr($val,0,1) eq '/') ?
      $val : "$home/$val";
   DiveVal($hash2, map \$_, @path) = $new_val;
#  dive_val($hash3, map \$_, @path) = $new_val;
}
die Dumper \@paths,\%hash1,$hash2;
sub dive {
   my $r = shift;
   $r = $r->{shift(@_)} while $r && @_;
   return $r;
}
sub dive_val :lvalue {
   my $p = \shift;
   my $r = \( $$p->{$_} ) for @_;
   $$p
}

      [download]
[reply]
[d/l]

        $r should be $p. Should have been obvious since strict catches that error. Fixed in original.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom