in reply to splinting a line of text by comma

And here's one that handles multiple columns with commas: 

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1226189

use strict;
use warnings;

while( <DATA> )
  {
  my @queue = $_;
  while( @queue )
    {
    local $_ = shift @queue;
    if( /\|([^|,]*(?:,[^|,]*)+)\|/ )
      {
      push @queue, map "$`|$_|$'", split /,/, $1;
      }
    else
      {
      print;
      }
    }
  }

__DATA__
 some text FOO | some text BAR | oh , no , commas | some text BAZ | so
+me text QUX
 some text FOO | some text BAR | single | some text BAZ | some text QU
+X
 some text FOO | some text BAR | oh , no , commas | one, two | some te
+xt QUX

[download]

Outputs: 

 some text FOO | some text BAR | oh | some text BAZ | some text QUX
 some text FOO | some text BAR | no | some text BAZ | some text QUX
 some text FOO | some text BAR | commas | some text BAZ | some text QU
+X
 some text FOO | some text BAR | single | some text BAZ | some text QU
+X
 some text FOO | some text BAR | oh | one| some text QUX
 some text FOO | some text BAR | oh | two | some text QUX
 some text FOO | some text BAR | no | one| some text QUX
 some text FOO | some text BAR | no | two | some text QUX
 some text FOO | some text BAR | commas | one| some text QUX
 some text FOO | some text BAR | commas | two | some text QUX

[download]

Replies are listed 'Best First'.
Re^2: splinting a line of text by comma (updated)
by AnomalousMonk (Archbishop) on Nov 23, 2018 at 00:09 UTC

    Rather than iterating through every permutation of every comma-separated sub-phrase, wouldn't it be better to print each set of sub-phrases once per line? Also, comma-separated sub-phrases at the beginning or end of the line will not be processed. How about something like: 

    c:\@Work\Perl\monks>perl -wMstrict -le
"my @lines = (
   'some text foo | some text BAR | oh , no , commas | some text BAZ |
+ some text QUX',
   'some text Oof | some, text, BAR | some , text , BAZ | some text QU
+X',
   'some, text, FOO | some text BAR |  one two | some , text , QUX',
   );
 ;;
 my $got_commas = qr{
   (?: (?<= [|]) | \A) [^|,]* (?: , [^|,]*)+ (?= [|] | \z)
   }xms;
 ;;
 for my $line (@lines) {
   while ($line =~ m{ ($got_commas) }xmsg) {
     my $before = substr $line, 0, $-[1];
     my $after  = substr $line, $+[1];
     print qq{:$before$_$after:} for split m{ , }xms, $1;
     }
   }
"
:some text foo | some text BAR | oh | some text BAZ | some text QUX:
:some text foo | some text BAR | no | some text BAZ | some text QUX:
:some text foo | some text BAR | commas | some text BAZ | some text QU
+X:
:some text Oof | some| some , text , BAZ | some text QUX:
:some text Oof | text| some , text , BAZ | some text QUX:
:some text Oof | BAR | some , text , BAZ | some text QUX:
:some text Oof | some, text, BAR | some | some text QUX:
:some text Oof | some, text, BAR | text | some text QUX:
:some text Oof | some, text, BAR | BAZ | some text QUX:
:some| some text BAR |  one two | some , text , QUX:
: text| some text BAR |  one two | some , text , QUX:
: FOO | some text BAR |  one two | some , text , QUX:
:some, text, FOO | some text BAR |  one two | some :
:some, text, FOO | some text BAR |  one two | text :
:some, text, FOO | some text BAR |  one two | QUX:

    [download]
    (Availability of  \K with Perl versions 5.10+ can make the  (?: (?<= [|]) | \A)) expression a little nicer.)

    Update: An "impure" variation. No big improvement; maybe of some interest. 

    c:\@Work\Perl\monks>perl -wMstrict -le
"my @lines = (
   'some text foo | some text BAR | oh , no , commas | some text BAZ |
+ some text QUX',
   'some text Oof | some, text, BAR | some , text , BAZ | some text QU
+X',
   'some, text, FOO | some text BAR |  one two | some , text , QUX',
   );
 ;;
 my $got_commas = qr{
   (?: (?<= [|]) | \A) [^|,]* (?: , [^|,]*)+ (?= [|] | \z)
   }xms;
 ;;
 local our @out;
 use re 'eval';
 m{ \A (.*?) ($got_commas) (?= (.*))
    (?{ push @out, map qq{>$1$_$3<}, split m{ , }xms, $2 })
    (?!)
    }xmsg
    for @lines;
 ;;
 print for @out;
"
>some text foo | some text BAR | oh | some text BAZ | some text QUX<
>some text foo | some text BAR | no | some text BAZ | some text QUX<
>some text foo | some text BAR | commas | some text BAZ | some text QU
+X<
>some text Oof | some| some , text , BAZ | some text QUX<
>some text Oof | text| some , text , BAZ | some text QUX<
>some text Oof | BAR | some , text , BAZ | some text QUX<
>some text Oof | some, text, BAR | some | some text QUX<
>some text Oof | some, text, BAR | text | some text QUX<
>some text Oof | some, text, BAR | BAZ | some text QUX<
>some| some text BAR |  one two | some , text , QUX<
> text| some text BAR |  one two | some , text , QUX<
> FOO | some text BAR |  one two | some , text , QUX<
>some, text, FOO | some text BAR |  one two | some <
>some, text, FOO | some text BAR |  one two | text <
>some, text, FOO | some text BAR |  one two | QUX<

    [download]

    Give a man a fish:  <%-{-{-{-<

[reply]
[d/l]
[select]

      That is printing lines with commas. How about this with just a small tweak to allow commas in the first and/or last field. 

      #!/usr/bin/perl

# https://perlmonks.org/?node_id=1226189

use strict;
use warnings;

while( <DATA> )
  {
  my @queue = $_;
  while( @queue )
    {
    local $_ = shift @queue;
    if( / [^|,\n]* (?: , [^|,\n]* )+ /x )
      {
      push @queue, map "$`$_$'", split /,/, $&;
      }
    else
      {
      print;
      }
    }
  }

__DATA__
some text foo | some text BAR | oh , no , commas | some text BAZ | som
+e text QUX
some text Oof | some, text, BAR | some , text , BAZ | some text QUX
some,text,FOO | some text BAR |  one two | some , text , QUX

      [download]

      Outputs: 

      some text foo | some text BAR | oh | some text BAZ | some text QUX
some text foo | some text BAR | no | some text BAZ | some text QUX
some text foo | some text BAR | commas | some text BAZ | some text QUX
some text Oof | some| some | some text QUX
some text Oof | some| text | some text QUX
some text Oof | some| BAZ | some text QUX
some text Oof | text| some | some text QUX
some text Oof | text| text | some text QUX
some text Oof | text| BAZ | some text QUX
some text Oof | BAR | some | some text QUX
some text Oof | BAR | text | some text QUX
some text Oof | BAR | BAZ | some text QUX
some| some text BAR |  one two | some 
some| some text BAR |  one two | text 
some| some text BAR |  one two | QUX
text| some text BAR |  one two | some 
text| some text BAR |  one two | text 
text| some text BAR |  one two | QUX
FOO | some text BAR |  one two | some 
FOO | some text BAR |  one two | text 
FOO | some text BAR |  one two | QUX

      [download]
[reply]
[d/l]
[select]
        ... one of the columns has multiple values separated with a comma like an array. ... unwind the array so each value of the array is on a separate line and all other fields are duplicated or carried with it ... [from the OP]

        Admittedly not the clearest specification. I was focusing on the "... all other fields are duplicated or carried with it ..." part, which I took to mean that some other fields with commas might be printed.

        ... mongo documentation of $unwind does what I'd like ...

        I don't understand what this means. Is "mongo" a thing?

        Give a man a fish:  <%-{-{-{-<

[reply]
[d/l]

In Section Seekers of Perl Wisdom