Hi,

• use a regular expression to extract the meaningful part of the value in the given cells
• use the CSV-parsing library Text::CSV_XS to read in the first file and create a hash containing a key for each value that should not be duplicated
• use the library again to read in the second file
• use the filter option (as recently shown by choroba) to exclude rows with seen values
• use map to reduce the wanted rows to just the values

(Note I am using Inline::Files here to provide this demo script with CSV files. In real life, replace "\*FILE1" and "\*FILE2" with the real file names.)

use v5.014;
use Text::CSV_XS 'csv';

my $re = qr/ \A first (?:\s|\.) last \( (G[0-9]+) \) \Z /x;

my %hash = map { ($_->[3] =~ s/$re/$1/r) => 1 } @{
    csv( in => \*FILE1, headers => 'skip' ),
};

my @result = map { $_->[0] } @{
    csv( in => \*FILE2, headers => 'skip', filter => {
        1 => sub { $_ =~ s/$re/$1/ and not exists $hash{$_} },
    }),
};

say "found $_ " for @result;

use Inline::Files;
__FILE1__
"A","B","C","D","E"
"blah","blah","blah","first last(G123456)","blah"
"blah","blah","blah","first last(G123457)","blah"
"blah","blah","blah","first last(G123459)","blah"
__FILE2__
"A","B","C","D"
"first.last(G123456)","blah","blah","blah"
"first.last(G123457)","blah","blah","blah"
"first.last(G123458)","blah","blah","blah"
"first.last(G123459)","blah","blah","blah"
[download]

Output:

$ perl 1226797.pl

found G123458
[download]

Hope this helps!