It seems that Web::Scraper uses HTML::TreeBuilder::XPath, and HTML::TreeBuilder has an no_space_compacting option that is disabled by default, causing that module to do s/[\n\r\f\t ]+/ /g by default. At the moment I don't see a way to set arbitrary options on the parser via Web::Scraper, this is probably worth opening an issue for.

Two workarounds I see at the moment: replacing Web::Scraper with Web::Scraper::LibXML works for me:

use warnings;
use strict;
use Data::Dump;
use Web::Scraper::LibXML;

my $scraper = scraper {
        process '//p[contains(@class, "myClass")]',
            'paragraph' => 'TEXT';
    };

dd $scraper->scrape(\<<'END_HTML');
<p class="myClass">Blah

Blah

Blah
</p>
END_HTML

__END__

{ paragraph => "Blah\n\nBlah\n\nBlah\n" }
[download]

Or, monkey-patching Web::Scraper::build_tree:

*Web::Scraper::build_tree = sub {
    my($self, $html) = @_;
    my $t = HTML::TreeBuilder::XPath->new;
    $t->store_comments(1) if ($t->can('store_comments'));
    $t->no_space_compacting(1);
    $t->ignore_unknown(0);
    $t->parse($html);
    $t->eof;
    $t;
};
[download]