davorg has asked for the wisdom of the Perl Monks concerning the following question:

According to the documentation Attribute::Handlers is "an excellent and intuitive interface through which to tie variables". I've tied a few variables in my time so I thought I'd give it a go.

But I think I'm misunderstanding it, as it doesn't give me the results I expect.

Here's a simple tied hash (that doesn't do anything useful)

#!/usr/bin/perl -w

package Tie::Hash::Test;
use Tie::Hash;
use vars qw(@ISA);
@ISA = 'Tie::StdHash';
sub TIEHASH {
  my $class = shift;

  my %self;
  @self{@_} = (undef) x @_;

  bless \%self, $class;
}

package main;

tie my %hash, 'Tie::Hash::Test', 'one', 'two', 'three';

print join(':', keys %hash), "\n";

[download]

Running this code gives the expected results of:

one:three:two

[download]

Here's the same tied hash using attributes:

#!/usr/bin/perl -w

package Tie::Hash::Test;
use Tie::Hash;
use Attribute::Handlers autotie => { __CALLER__::Test => __PACKAGE__ }
+;
use vars qw(@ISA);
@ISA = 'Tie::StdHash';
sub TIEHASH {
  my $class = shift;

  my %self;
  @self{@_} = (undef) x @_;

  bless \%self, $class;
}

package main;

my %hash : Test('one', 'two', 'three');

print join(':', keys %hash), "\n";

[download]

Running this code gives the result:

ARRAY(0x80f551c)

[download]

Which isn't quite what I expected.

Has anyone else tried this? Have you had better luck?

--
<http://www.dave.org.uk>

"The first rule of Perl club is you don't talk about Perl club."

Replies are listed 'Best First'.
Re: autotie in Attribute Handlers
by TheDamian (Vicar) on Nov 04, 2001 at 17:13 UTC
    According to the documentation Attribute::Handlers is "an excellent and intuitive interface through which to tie variables".

    Oh, and, lest I be accused of self-aggrandisement, the documentation actually says:

    Attributes make an excellent and intuitive interface through which to tie variables.

    I make no claims about Attribute::Handlers.

    ;-)

[reply]
Re (tilly) 1: autotie in Attribute Handlers
by tilly (Archbishop) on Nov 03, 2001 at 09:17 UTC
    I looked at the code, and it looks to me to be a bug, but I don't know for sure what TheDamian intended.

    Here is what is happening. Your argument list is always being turned into a reference to an array. If you process it that way in your tie implementation, it works just fine. If you don't, then you get your result.

    Now if you look in the implementation, in import the variable $tiedata is defined in the following snippet: 

            if ($cmd =~ /^autotie((?:ref)?)$/) {
            my $tiedata = '($was_arrayref ? $data : @$data)';
               $tiedata = ($1 ? '$ref, ' : '') . $tiedata;
            my $mapping = shift;

    [download]
    Now that looks to me to be an error, if you had an array reference, then leave it alone, if you didn't then try to dereference it as an array reference? If you didn't have an array reference, what possible sense does it make to dereference it as one?

    Well if you try switching which branch of the trinary operator the array dereference takes place in, that code reads much more sensibly, and your test works entirely as you expected it to. However if you do that, 2 tests in the test suite fail. So I suspect that this is a bug in the code which was enshrined in the tests.

    But I can't be sure of that without asking TheDamian. (I sent him a message.)

[reply]
[d/l]
      Now that looks to me to be an error, if you had an array reference, then leave it alone, if you didn't then try to dereference it as an array reference? If you didn't have an array reference, what possible sense does it make to dereference it as one?

      No, the code you're querying is correct. You're missing the fact that the autogenerated handler also has this line in it: 

          \$data = [ \$data ] unless \$was_arrayref;

      [download]

      So the effect of that code is to pass array refs to tie as array refs, and non-array-refs to tie as lists.

      There is a bug here, but it was elsewhere: namely that the codewasn't correctly distinguishing between an attribute with a list of args (:Attr('list','of','args')) and an attribute with a single array ref as an arg (:Attr(['list','of','args'])). I've now fixed that.

      There's a beta at http://www.csse.monash.edu.au/~damian//CPAN/Attribute-Handlers.tar.gz. Perhaps you and/or Marcel would like to see if it behaves more intuitively for you.

[reply]
[d/l]
[select]
        That beta does fix that issue, but I consider its behaviour with the following line to be wrong: 
        my %hash : Test('one', 'two', 'three)');

        [download]
        Any human looking at this would say that the first closing paren is inside of a quoted string, and so this code is correct. But Attribute::Handlers disagrees. It is perfectly willing to stop at the first paren, and claim that the passed argument was the string: 
        "'one', 'two', 'three"

        [download]
        And therefore the following quote is interpreted differently than it should be.

        I assume that this is due to the heuristics it uses to parse Perl. If it is hard to fix (as I assume) then it is probably something to solve in 6.0. But I think it is a gotcha worth noting, along with the workaround: 

        my %hash : Test('one', 'two', 'three\)');

        [download]
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom