Re^10: Export and use different package in module

Thank you, this is a very informative reply, also for being patient with me. My Perls were version 24 and 22, so I was just a few versions short.

A side note I didn't think about, can a scalar be substituted in a scalar name? I think it was strict refs that complains if you use a scalar as the name of a hash, which might be why the earlier example you showed me needed it (if following the same rules). If I could just do ${pi} = "biglonglibraryname::subthing::", I wouldn't have to breach scope, and I could get a short name. Thanks again.

Comment on Re^10: Export and use different package in module

Replies are listed 'Best First'.
Re^11: Export and use different package in module by haukex (Archbishop) on Feb 23, 2019 at 14:33 UTC
A side note I didn't think about, can a scalar be substituted in a scalar name? Yes, the mechanism basically works for any package variables (scalars, arrays, hashes, filehandles, etc.) and `sub`s. It doesn't work for lexical variables, i.e. those declared with `my`. `package Big::Long::Library::Name { our $scalar = "Foo"; our @array = qw/ Bar Quz /; our %hash = ( Baz => 42 ); sub function { print "Hello\n" } } package MyPackage { BEGIN { MyPackage::blah = \&Big::Long::Library::Name::function; package Foo; MyPackage::myscalar = \$Big::Long::Library::Name::scalar; MyPackage::array = \@Big::Long::Library::Name::array; MyPackage::hash = \%Big::Long::Library::Name::hash; } print "$myscalar @array $hash{Baz}\n"; blah; }` [download] I had to put the operations in a `BEGIN` block so that Perl knows about the variable names at compile time, and the `package Foo;` is there because of this detail. As a slightly nicer alternative, you can use Symbol::Alias: `package Big::Long::Library::Name { our $scalar = "Foo"; our @array = qw/ Bar Quz /; our %hash = ( Baz => 42 ); sub function { print "Hello\n" } } package MyPackage { use Symbol::Alias 'Big::Long::Library::Name::function' => 'blah', '$Big::Long::Library::Name::scalar' => 'myscalar', '@Big::Long::Library::Name::array' => 'array', '%Big::Long::Library::Name::hash' => 'hash'; print "$myscalar @array $hash{Baz}\n"; blah; }` [download]	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^11: Export and use different package in module
by haukex (Archbishop) on Feb 23, 2019 at 14:33 UTC

A side note I didn't think about, can a scalar be substituted in a scalar name?

Yes, the mechanism basically works for any package variables (scalars, arrays, hashes, filehandles, etc.) and subs. It doesn't work for lexical variables, i.e. those declared with my.

package Big::Long::Library::Name {
    our $scalar  = "Foo";
    our @array   = qw/ Bar Quz /;
    our %hash    = ( Baz => 42 );
    sub function { print "Hello\n" }
}
package MyPackage {
    BEGIN {
        *MyPackage::blah =     \&Big::Long::Library::Name::function;
        package Foo;
        *MyPackage::myscalar = \$Big::Long::Library::Name::scalar;
        *MyPackage::array =    \@Big::Long::Library::Name::array;
        *MyPackage::hash =     \%Big::Long::Library::Name::hash;
    }
    print "$myscalar @array $hash{Baz}\n";
    blah;
}
[download]

I had to put the operations in a BEGIN block so that Perl knows about the variable names at compile time, and the package Foo; is there because of this detail. As a slightly nicer alternative, you can use Symbol::Alias:

package Big::Long::Library::Name {
    our $scalar  = "Foo";
    our @array   = qw/ Bar Quz /;
    our %hash    = ( Baz => 42 );
    sub function { print "Hello\n" }
}
package MyPackage {
    use Symbol::Alias
        'Big::Long::Library::Name::function' => 'blah',
        '$Big::Long::Library::Name::scalar'  => 'myscalar',
        '@Big::Long::Library::Name::array'   => 'array',
        '%Big::Long::Library::Name::hash'    => 'hash';
    print "$myscalar @array $hash{Baz}\n";
    blah;
}
[download]

[reply]
[d/l]
[select]