Hi again,

If needed, workers may write output orderly and efficiently via MCE::Relay simply by passing the init_relay option. The value to init_relay is not used in the demonstration. Just the block to MCE::relay which runs serially and orderly.

#!/usr/bin/env perl
use strict;
use warnings;
use MCE;

use constant MAX_ITEMS => 200000;

$| = 1; # necessary when workers output orderly

my $n_workers = shift // do {
    die "usage: $0 n_workers\n";
};

sub isPrime {
    my $num = shift;
    return 1 if ($num < 4);
    return 0 if ($num %2 == 0);
    for (my $i=3; $i <= sqrt($num); $i+=2) {
        return 0 if $num % $i == 0;
    }
    return 1;
}

sub task {
    my ( $mce, $seq, $chunk_id ) = @_;
    my $output = '';
    for my $data ( $seq->[0] .. $seq->[1] ) {
        $output .= "Prime: $data\n" if isPrime($data);
    }
    MCE::relay { print $output };
}

MCE->new(
    max_workers => $n_workers,
    sequence    => [ 1, MAX_ITEMS ],
    bounds_only => 1,
    chunk_size  => 200,
    user_func   => \&task,
    init_relay  => 1,
)->run();
[download]

Regards, Mario