Hello dideod.yang,

You can make your first foreach loop work with eval:

foreach my $array (@array)
{
    eval "$array->()";
}
[download]

However, for reasons outlined in How can I use a variable as a variable name?, this is usually a bad idea. A better approach is to build a lookup table using a hash:

my %test_functions =
(
    test  => \&test,
    test2 => \&test2,
    test3 => \&test3,
);

$test_functions{$_}->() for qw/ test test2 test3 /;
[download]

Hope that helps,

Along these lines, Implementing Dispatch Tables has some more information that might be helpful.

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1230776

use strict;
use warnings;
## examples of sub_function.
sub test { print "test\n" }
sub test2 {print "test2\n" }
sub test3 {print "test3\n" }

## pair up variables with sub_function.
my $test = \&test;
my $test2 = \&test2;
my $test3 = \&test3;

#my @array = qw/ test test2 test3 /;
my @array = ( $test, $test2, $test3 );

foreach my $array (@array) {
             $array->()
                           }
[download]

<update> Sorry, I wasn't quite awake yet, my reply below isn't as relevant to the question as I thought it was... Athanasius is right: using a hash table is IMO best (don't use eval or symbolic references). And tybalt89 showed how to make an array of coderefs, which is another good option, depending on your requirements (it doesn't allow you to look up stuff by name). </update>

To deference a code reference, one would normally use $coderef->(). It's also possible to say &$coderef() or &$coderef, but the first form is more modern. See perlreftut, perlref, and perlsub.

I'm not sure what you mean by the second part of your question, whether you want to call the subs, or get their original name? If it's the latter:

use Sub::Util qw/subname/;
sub foo {}
my $test = \&foo;
print subname($test);  # prints "main::foo"
[download]

Sub::Util has been in the core since Perl v5.22.

And now for something completely different :)

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1230776

use strict;
use warnings;

## pair up variables with sub_function.
my @array = qw/ test test2 test3 /;
my %easyily;
for my $array ( @array )
  {
  $easyily{$array} = sub { print "$array\n" };
  }

for my $array ( @array )
  {
  $easyily{$array}()
  }
[download]

Not sure what you are looking for. May be it is something like my $testomato = sub {shift};. You call it as say $testomato->(q(test));. Regards, Karl.