There are a couple of ways which you could achieve this ...

• If all you want to do is capture fatal errors and events, you should have a look at CGI::Carp which allows you to redirect fatal error messages to the web client in the following fashion:

  use CGI::Carp qw/fatalsToBrowser/;
  die "Something bad happened";
  [download]

  Fatal errors will now be echoed to the browser as well as to the HTTPD error log. CGI::Carp sends a minimal HTTP header to the browser so that even errors that occur in the early compile phase will be seen. However, with this method, non-fatal errors will still be directed only to the HTTPD error log (see below).

• Non-fatal warning errors can be trapped through the trapping of the __WARN__ signal for which custom handler subroutines can be executed. eg.

  $SIG{__WARN__} = sub {
      print STDOUT "Content-Type: text/plain\n\n";
      print STDOUT @_, "\n";
      exit 0;
  };
  [download]

  This of course could be combined with the CGI::Carp module as follows:

  use CGI::Carp qw/fatalsToBrowser/;
  $SIG{__WARN__} = sub { die @_; };
  [download]

  The problem however with this approach (and indeed the other anonymous subroutine described) is that non-fatal script warnings are treated as fatal errors - This of course will tighten up your code, but is admittedly quite a zealous approach to the matter. A cleaner method may be the incorporation of this trapping into an email reporting function, which sends the script warnings (along with a dump of environment variables and configuration arguments) to you via email rather than to the browser screen in a fatalistic fashion. eg.

  use CGI::Carp qw/fatalsToBrowser/;
  use Mail::Mailer;
  
  #   Rough code follows, not to be used in current form 
  
  $SIG{__WARN__} = sub {
      my $smtp = Mail::Mailer->new("smtp", Server => "127.0.0.1");
      $smtp->open({
          'To'        =>  'webmaster@your.domain.com',
          'From'      =>  'nobody@your.domain.com'
      });
      print $smtp @_, "\n";
      $smtp->close;
  };
  [download]

 

Ooohhh, Rob no beer function well without!