I want to a regex which is able to match a-zA-Z0-9_- and parantheses.

SSCCE:

use strict;
use warnings;

use Test::More;

my @good = (
    'a',
    '321',
    '(321)',
    'a(321-)_HGF'
);

my @bad = (
    '"@$',
    '~',
    '[{'
);

my $re = qr/^[a-zA-Z0-9_()-]+$/;

plan tests => @good + @bad;

for my $str (@good) {
    like ($str, $re, "$str matched");
}
for my $str (@bad) {
    unlike ($str, $re, "$str not matched");
}
[download]

See also How to ask better questions using Test::More and sample data

This seems to be such an elegant little script for dealing with character classes but also the hyphen. I replicated it and save such scripts for the rainy day when I wonder how to do exactly this. I changed the data slightly to satisfy myself that that hyphen matched.

$ ./1.hippo_regex.pl 
1..7
ok 1 - a matched
ok 2 - - matched
ok 3 - (321) matched
ok 4 - a(321-)_HGF matched
ok 5 - "@$ not matched
ok 6 - ~ not matched
ok 7 - [{ not matched
[download]

Source:

#!/usr/bin/perl -w
use 5.011;
use Test::More;

my @good = (
    'a',
    '-',
    '(321)',
    'a(321-)_HGF'
);

my @bad = (
    '"@$',
    '~',
    '[{'
);

my $re = qr/^[a-zA-Z0-9_()-]+$/;

plan tests => @good + @bad;

for my $str (@good) {
    like ($str, $re, "$str matched");
}
for my $str (@bad) {
    unlike ($str, $re, "$str not matched");
}
[download]

_-( inside a character class ([ between square brackets ]) mean "any character between _ and (". It might have included a lot of characters you didn't want, but actually in this case, if you look at an ASCII table, you'll see that ( actually comes before _, so this is not a valid range.

It will also easier for us to help you if you show us some sample input data.

For handling  - (hyphen) characters in character classes, see Using character classes in perlrequick, which says in part:

The special character '-' acts as a range operator within character classes ...

If '-' is the first or last character in a character class, it is treated as an ordinary character.

See also a similar discussion in Using character classes in perlretut.

Update: And see also Bracketed Character Classes, Special Characters Inside a Bracketed Character Class and Character Ranges in perlrecharclass.

] and - are special in character classes.

As rules of thumb avoiding ambiguity°:

If needed ...

• use ] as first character
• use - as last character

update

D:\>perl -dE0

Loading DB routines from perl5db.pl version 1.49_05
Editor support available.

Enter h or 'h h' for help, or 'perldoc perldebug' for more help.

  DB<1> say "$_:\t", $_ =~ /[]abc-]/ for qw/] [ - a/
]:      1
[:
-:      1
a:      1

  DB<2>
[download]

°) Otherwise ] will close the class and - will denote a range.

Do you want to match any parenthesis, bracket, brace, or do you want to match them balanced?

try enclosing your ranges in square brackets which roughly means "one of these characters": [A-Za-z0-9_()]