timpoiko has asked for the wisdom of the Perl Monks concerning the following question:

Hello monks. I tried to write a rough brainf*ck-2-c translator. 
#!/usr/bin/perl
use strict;

open (DATA,$ARGV[0]) or die "unable to open";

print "#include <stdio.h>\n#include <stdlib.h>\n\n";
print "int main(void) {\n\tunsigned char *k = calloc(2000, 1);\n";

while (<DATA>) {
        s/>/\t\t++k;\n/g;
        s/</\t\t--k;\n/g;
        s/\+/\t\t++*k;\n/g;
        s/\-/\t\t--*k;\n/g;
        s/\./\t\tputchar(*k);\n/g;
        s/\,/\t\t*k = getchar();\n/g;
        s/\[/\twhile (*k) {\n/g;
        s/\]/\t}\n/g;
        print "$_";
}

close DATA;

print "\treturn 0;\n}\n";

[download]

I can't understand why output of s/>/\t\t++k;\n/g; and s/</\t\t--k;\n/g; is so weird, ie. missing plus and minus signs, missing tabs.

Sample bf-code:
+[----->+++<]>+.---.+++++++..+++.[--->+<]>-----.--[->++++<]>-.--------.+++.------.--------. 

$ perl -v

This is perl 5, version 20, subversion 2 (v5.20.2)

[download]

Replies are listed 'Best First'.
Re: Weird substitution, missing output
by Anonymous Monk on May 10, 2019 at 11:47 UTC

    Suppose you have a program consisting of just >. What happens to it when you run your code:

    1. s/>/\t\t++k;\n/g; transforms it into \t\t++k;\n
    2. s/</\t\t--k;\n/g; does nothing, it's still \t\t++k;\n
    3. s/\+/\t\t++*k;\n/g; transforms each + present in the program into \t\t++*k;\n, leaving you with \t\t\t\t++*k;\n\t\t++*k;\nk;\n
    One way to solve it would be to create a hash of all possible replacements: 
    my %sub = {
 ">" => "\t\t++k;\n",
 "+" => "\t\t++*k;\n",
 ... # fill as needed
}

    [download]
    Then run the substitution only once, on each symbol: 
    s/(.)/$sub{$1}/ge

    [download]
    Fixing the warnings about undefined hash elements (when do they happen?) and/or constructing a regular expression that would only match brainf*ck characters is left as an exercise for the reader.

    A faster, but less elegant solution would be to replace + and - first, then consider other characters which might produce their own [+-].

[reply]
[d/l]
[select]
      my %sub = {
 ">" => "\t\t++k;\n",
 "+" => "\t\t++*k;\n",
 ... # fill as needed
 }

      [download]

      The hash initialization statement above should use parentheses and not curlies:
          my %sub = ( ... );

      s/(.)/$sub{$1}/ge

      Also note that the  /e modifier is not needed in this substitution (although it does no harm except to burn some time) because  $sub{$1} is already a scalar that can be interpolated into a string.

      Give a man a fish:  <%-{-{-{-<

[reply]
[d/l]
[select]
        Thanks for the corrections. I should have noted that my reply was prepared on a mobile device and mostly untested.
[reply]
      Thank you. Because this is a rough translator, I fixed this using non elegant method. 
              s/</\t\tAAk;\n/g;
        s/>/\t\tBBk;\n/g;
        s/\+/\t\tAA*k;\n/g;
        s/\-/\t\tBB*k;\n/g;
        s/\./\t\tputchar(*k);\n/g;
        s/\,/\t\t*k = getchar();\n/g;
        s/\[/\twhile (*k) {\n/g;
        s/\]/\t}\n/g;
        s/A/+/g;
        s/B/-/g;

      [download]
[reply]
[d/l]
        You seem to also want indentation with "\t", which means you need to keep count of the loop levels.

        Here a much easier to maintain code, looping over a split and keeping track of indentation.

        And you can easily adapt this code to emit other languages - like Perl° - too, without worrying about polluted input.

        use strict;
use warnings;
#use Data::Dump qw/pp dd/;
#use feature qw/say/;

my @table = split /\n/, <<'__TABLE__';
>    ++k;
<    --k;
+    ++*k;
-    --*k;
.    putchar(*k);
,    *k = getchar();
[    while (*k) {
]    }
__TABLE__

my %trans = map { split/\s+/, $_, 2 } @table;
#pp \%trans;



my $bfs   = '+[--[--]->+++<]>+.---';
my $level = 0;

for my $atom ( split //, $bfs ) {

    $level-- if $atom eq "]";
    print "\t" x $level;
    $level++ if $atom eq "[";
    
    print $trans{$atom};
    #print "\t\t\t// was '$atom'";         # debug
    print "\n";
}

        [download]

        ++*k;
while (*k) {
    --*k;
    --*k;
    while (*k) {
        --*k;
        --*k;
    }
    --*k;
    ++k;
    ++*k;
    ++*k;
    ++*k;
    --k;
}
++k;
++*k;
putchar(*k);
--*k;
--*k;
--*k;

        [download]

        Cheers Rolf
        (addicted to the Perl Programming Language :)
        Wikisyntax for the Monastery FootballPerl is like chess, only without the dice

        update

        °) which would allow you to use the perldebugger to step thru BF code.

        update

        changed code to improve readability

[reply]
[d/l]
[select]
Re: Weird substitution, missing output
by LanX (Saint) on May 10, 2019 at 11:38 UTC
    Hello

    Please show us the expected output and what you got for a short example input.

    See also SSCCE

    Cheers Rolf
    (addicted to the Perl Programming Language :)
    Wikisyntax for the Monastery FootballPerl is like chess, only without the dice

    Update

    After reading brainfuck I'm understanding your problem is that you are inserting + symbols as c-code which is replaced later as BF code.

    Translating linear code with a series of global s///g substitutions rarely works, because you are running over your own output.

    But Anonymous Monk has already given you an excellent answer in the meantime.

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom