You want to use eval(), I'd say. This is almost exactly a section of my book that I wrote last night!

open REs, "< re_file" or die "can't read re_file: $!";
while (<REs>) {
  chomp;
  my $mode = substr($_, 0, 1, '');  # reverse-chop
  push @re, [ $mode, match_maker($_) ];
}
close REs;


# make me a match... ;)
sub match_maker {
  my $pat = shift;
  return eval qq{ sub { \$_[0] =~ $pat } };
}
[download]

If you call match_maker($foo), and $foo is '/age:\s*(\d+)/i', then the resulting function returned behaves exactly like:

sub { $_[0] =~ /age:\s*(\d+)/i }

Now you have an array, @re, with array references holding the mode ('+' or '-') and a function you can run to match against a string.

for (@re) {
  my ($mode, $func) = @$_;
  if ($func->($string)) {  # this is your pattern match!
    if ($mode eq '+') { print "this is ok\n"; }
    else { print "this matched an exception\n"; }
  }
}
[download]

_____________________________________________________
Jeff[japhy]Pinyan: Perl, regex, and perl hacker.
s++=END;++y(;-P)}y js++=;shajsj<++y(p-q)}?print:??;