So keep aware of the option of doing this with a goto. But remember in any language to look for named loops. If they exist, then that is a better solution to this problem.

while my $foo (@bars) {
    if ($foo =~ /baz/i) {
        goto DONE unless $foo eq uc $foo;
    } else {
        goto DONE unless $foo ne uc $foo;
    }

    DONE:
    do_more_stuff($foo);
}
[download]

This doesn't work with next or redo. It works with continue.

------
We are the carpenters and bricklayers of the Information Age.

Don't go borrowing trouble. For programmers, this means Worry only about what you need to implement.

foreach my $foo (@bars) {
  {
    if ($foo =~ /baz/i) {
      last unless $foo eq uc $foo;
    } else {
      last unless $foo ne uc $foo;
    }
    # stuff
  }
  do_more_stuff($foo);
}
[download]

works just fine. There are several other options as well. First there is the continue that you mentioned:

foreach my $foo (@foos) {
  if ($foo =~ /baz/i) {
    next unless $foo eq uc $foo;
  } else {
    next unless $foo ne uc $foo;
  }
  # stuff
} continue {
  do_more_stuff($foo);
}
[download]

and then (depending on what you do in the if statement) there is reversing the order of your operations:

foreach my $foo (@foos) {
  do_more_stuff($foo);

  if ($foo =~ /baz/i) {
    next unless $foo eq uc $foo;
  } else {
    next unless $foo ne uc $foo;
  }
  # stuff
}
[download]

You can have the chain of ifs be replaced by a function call that returns from multiple points:

foreach my $foo (@foos) {
  do_stuff($foo);
  do_more_stuff($foo);
}

sub do_stuff {
  my $foo = shift;

  if ($foo =~ /baz/i) {
    return unless $foo eq uc $foo;
  } else {
    return unless $foo ne uc $foo;
  }
  # stuff
}
[download]

And so on.

I have, in fact, used every one of these solutions except the goto one, and I prefer all of them to the goto solution. Why? Because I find each of them clearer, they allow me to see program flow in terms of following blocks. The goto forces me to see an element of program flow which is not some form of block. I don't like that. Furthermore, no matter how clearly the goto solution's intention may be, its use opens up the possibility of traps like this:

foreach (1..5) {
  print "Hello\n";
  goto DONE;
}
DONE:

foreach (1..5) {
  print "World\n";
  goto DONE;
}
DONE:
[download]

By contrast anything only relying on return and loop control statements can be much more easily verified correct based on local examination. (OK, in this case your goto construct is verifiably correct without looking at outside code. But it will take more time for most people to figure out why the one is verifiably OK while the other is demonstrably bad than it will to figure out my alternate solution.)

Again, this is not something I would use a goto for.

UPDATE
Fixed a thinko danger pointed out to me. last and next are not the same.

In such a case, it is generally more acceptable to spell goto as next or redo as needed, and the LABELs are often unnecessary as well :-)