#!/usr/bin/perl -w

use strict;

my @FILE = ('123|title|1/1/01','123|btitle|1/1/01','123|atitle|1/1/01'
+);

print @FILE,"\n";

my @output =
    map { $_->[0] }
sort { $a->[1] cmp $b->[1] }
map { [$_, (split(/\|/,$_))[1]] }
@FILE;

print @output,"\n";
[download]

grep> cd pub
grep> more beer
[download]

Or why even bother reading the file contents into an array?

#!/usr/bin/perl -wd

open( FILE, "file.dat" ) ||
        die "Cannot Open file ($!)\n";
my @output =  map { $_->[0] }
              sort { $a->[1] cmp $b->[1] }
              map { [$_, (split(/\|/,$_))[1]] }
              <FILE>;

close( FILE );

print @output, "\n";
[download]

-derby

Untested.

my @data;
foreach (<FILE>) {
    push @data,  [split( /\|/, $_, 3 ) ];
}

@data = sort { $a->[1] cmp $b->[1] } @data;

foreach ( @data )
{
    my ( $id_number, $title, $date ) = @$_;
    print "ID: $id_numer\tTitle: $title\tDate: $date\n";
}
[download]

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just click on the the link and check out our stats.

my @Data = ();

while my $line (<FILE>) {

    push @Data, {};
    @{$Data[-1]}{ 'ID', 'Title', 'Date' } = split( /\|/, $line );
}


@Data = sort { $a->{'Title'} cmp $b->{'Title'} } @Data;


foreach my $line ( @Data ) {

    print join( ' | ', @$line{ 'ID', 'Title', 'Date' } ), "\n";
}
[download]

If you don't want to use the transform, you can always sort multiple arrays by the order of one:

my @ids;
my @titles;
my @dates;

foreach $line (@FILE) {
    my($id_number, $title, $date) = split(/\|/,$line);
    push (@ids, $id_number);
    push (@titles, $title);
    push (@dates, $date);
}

my @sorted = sort { $titles[$a] cmp $titles[$b] } (0 .. $#titles);
@ids    = @ids[@sorted];
@titles = @titles[@sorted];
@dates  = @dates[@sorted];
[download]

Not quite as elegant looking as the Schwartzian Transform, but it will do the trick. Also, this will be easier to work with if you need to modify $title, $id_number, or $date in the foreach loop.

Thank you all.