brassmon_k: there are a few things that you need to do before you should start tackling issues like this. First, good formatting does not indicate good code, but poor formatting almost always indicates bad code. Further, any code over just a few lines needs to have strict and warnings turned on. There are exceptions to that rule, but you need to really apply and understand these rules before you break them. Also, try to factor out common elements in your code and then always, always, always test system calls for failure (in the code above, this is the open statement we're worried about).

Applying these rules of thumb to your code and using a split instead of a regex, we get the following:

#!/usr/bin/perl -w
use strict;
my $file = "/dave/MVPTEST/mvpdoc";

print "DateSearch = d\n";
print "Timesearch = t\n";

my $choice;
do 
{
    print "Make Your Choice: ";
    chomp( $choice = <STDIN> );
} until ( $choice =~ /^[DdTt]/ );

chomp(my $data = <STDIN>); # this will be the date or the time

open FILE, "< $file" or die "Cannot open $file for reading $!";

foreach my $line (<FILE>)
{
    my ( $in_date, $in_time ) = (split /\s+/, $line)[4,5];
    if ( ( $choice =~ /^[dD]/ && $data eq $in_date ) || ( $data eq $in
+_time ) )
    {
        print "\n$line\n";
    }
}

close FILE;
[download]

There are plenty of ways to clean that up from there. As for your original question, check out the Date::Calc module.

Hope this helps and Happy New Year! :)

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just click on the the link and check out our stats.

Don't read the entire file into an array -- that's slow, and it isn't necessary. Do something like

while (<>)
{
  next if ( $_ !~ /\d/ );  #  Skip records w/o numeric fields

  #  Match, print if within range here..
}
[download]

Also, don't try to do everything in one line -- even :) if Perl will let you do that. If I were doing this project, I would probably split the incoming data line into an array (splitting on spaces) and then deal with the individual elements. If the date matches a particular value, then I would look at the time, splitting it on the ':', comparing to the time range that you want.

--t. alex

"Excellent. Release the hounds." -- Monty Burns.

Note that you should prompt the user for the time range (begin and end times). Either that or specify that they type in the begin time for a given interval (seconds, minutes, hours). The first method would be simpler to implement. I've simplified your problem but you should get the gist of it:

use strict;

my ($beg, $end) = qw(00:01:20 00:02:20);
print "beg: $beg   end: $end\n";

print "Matches\n--------\n";
while (<DATA>) {
  chomp;
  if (($_ ge $beg) && ($_ le $end)) {
     print "$_\n";
  }
}

__DATA__
00:01:01
01:01:01
00:01:20
00:01:21
00:02:00
00:02:21
00:02:20
00:01:19
[download]

beg: 00:01:20   end: 00:02:20
Matches
--------
00:01:20
00:01:21
00:02:00
00:02:20
[download]

--Jim

I'll get back to you guys. I integrated what you 2 said and I got it working but I want to dress it up a bit. I'll show ya it when I'm done...It's pretty cool.