When I ran your program I got the "Expected" ouput rather than the "REAL" output. Perhaps your data source was different.

Just a few comments:

It would be better to use \d and \w in the date matching regex.
It would be better to use a negated character class to match the Inron/Exon data.
On the main loop it is better to use while instead of foreach
Braces don't have to be escaped in a quoted string.

while (<INFO1>) {
    if (/^DATE\s*(\d+)-(\w+)-(\d+)/) {
        print qq{\nDATE\t"$1-$2-$3"\n};
    }
    elsif (/\s*\/intron="([^"]+)/) {
        foreach my $item (split('\;',$1)) {
            print "Intron\t{Translation%$item}\n";
        }
    }
    elsif (/\s*\/exon="([^"]+)/) {
        foreach my $item (split('\;',$1)) {
            print "Exon\t{Translation%$item}\n";
        }
    }
}
[download]

The problem appears to be the format of your input file, and your regex. It looks like your files are using "\r\n" as the line terminator, but your script is running on a system that uses "\n" by default.

The .* matches all characters EXCEPT "\n", but the \r matches -- and it gets slurped up in the $n variables of your regexes. The result is that you are printing those \r's back out -- and when you print a \r in a terminal, it causes the cursor to return to the begining of the currentline, and the reamining text on that line overrites the existing text (in each case in your script, theres only one letter left prior to the next \n -- the double quote character.)

The simplest way to solve your problem, is probably to set $/ = "\r\n" prior to your for loop, and use chomp inside your loop (you should also get rid of those \n in your regexes -- they aren't needed.)

i think you should go back and read all the responses to your query. there's some good advice in there (okay, it's from me and trs80), including code samples *with comments!* that will help you understand what you are doing. also, there's some good recommended reading... no required reading. i'll put those links here again.

some nodes you might want to read are:
while or foreach?
Opening files
Use strict warnings and diagnostics or die
Death to Dot Star!

as well as shift, FileHandle, perlre, split, and while.

please, use strict!

~Particle

#!/usr/bin/perl -w
#A program that accept an input file: Scorpion database from Gen Bank
#and will output the database in BioWare format

my $file1="$ARGV[0]";        #var to save the input database
my $counter=1;

open(INFO1,$file1) or die "Can't open $file1.\n";#open file1
foreach(<INFO1>)
{
    if(/DATE\s*(.*)-(.*)-(.*)/){
    print 'DATE'."\t".'"'."$1-$2-$3".'"'."\n";
    }                                             
    elsif(/\s*\/intron=(.+)\n/) {
    my $item;
    my $local=$1;
    $local =~ s/\"//g;
    foreach $item (split('\;',$local)) {
        $item = " - " if $item =~ " ";
            print "Intron\t \{Translation%$item\}\n";
    }
    } #end elsif
    
    elsif(/\s*\/exon=(.+)\n/) {
    my $item;
    my $local=$1;
    $local =~ s/\"//g;
    foreach $item (split('\;',$local)) {
        $item = " - " if $item =~ " ";
        print "Exon\t", " \{Translation\%","$item\}","\n";
    }
    }
}
[download]

• Added a semicolon after  my $file1="$ARGV[0]"
  
• Removed the circonflex in   if(/^DATE\s*(.*)-(.*)-(.*)/)
  
• Added the if-statement to handle empty transaction-strings

michael@trul:~/> perl prog.pl input
DATE    "13-JUN-2000"
Exon     {Translation%49-333}
Intron   {Translation%1-48}
Intron   {Translation%334-385}
DATE    "14-JUN-2000"
Exon     {Translation%1-120}
Intron   {Translation% - }
[download]

Whether you have to escape your quotes or not depends on what kind of surrounding quotes you're using. If the surrounding quotes are ", then you don't have to escape ' qutoes, but other " quotes MUST be escaped (otherwise they mark the end of the string and will probably cause compilation errors). And vice versa.

If you are using a mixture of single and double quotes you may find it more comfortable the qq construct for strings:

   my $string = qq( A "string" with lots of 'quotes' );
[download]

I notice, BTW, that you open an output file but never writes anything to it; I assume that you changed this for debugging purposes... :)

Cheers,
-- moodster