1. Where did you get the package from? Did you install the ActiveState version?
2. Are you using ActiveState Perl? If so you can grab the ppm version.
3. Have you installed it in a non-standard place. You'll need to "use lib" if so.
4. If it is in a non-standard place, where did you put it?

sub send_outlook_mail
{
    #use OLE and Outlook to send an email message

    my $to = shift || croak "required parameter (to address) missing";
    my $subject = shift;
    $subject = "" if not defined $subject;
    my $body = shift;
    $body = "" if not defined $body;
    my $cc = shift;
    $cc = "" if not defined $cc;
    
    #get new Outlook instance
    my $mail = new Win32::OLE('Outlook.Application');
    croak "Unable to start Outlook instance: $!" if !defined $mail;
    
    my $item = $mail->CreateItem(0);
    croak "Unable to create mail item: $!" if !defined $item;
    
    $item->{'To'} = $to; 
    $item->{'CC'} = $cc;
    $item->{'Subject'} = $subject;
    $item->{'Body'} = $body; 
    
    #rest of args are file attachments
    foreach my $attach (@ARGV)
    {
    #    print STDERR "File attachment: $attach\n";
        #make sure the attachment is really there
        croak "Missing attachment $attach: $!" if !-e $attach;
    
        my $attachments = $item->Attachments();
        $attachments->Add($attach);
    }
    
    #send it
    $item->Send();
    
    my $error = Win32::OLE->LastError();
    carp "Win32::OLE error: $error" if $error;
    
} #sub send_outlook_mail
[download]

I've not used Mail::Mailer on NT but Mail::Sendmail works a treat (just make sure you set your smtp server). If you have Activestate's perl you can install it with PPM (just type ppm install Mail::Sendmail at a dos prompt). An example:

use Mail::Sendmail;
sendmail(To => $to, 
    From => $from, 
    Message => $msg,
    Subject => $subject,
    smtp => 'localhost') || die "Couldn't send email";
[download]

gav^

use Mail::Sendmail;
my %mail = (
            SMTP    => $SMTP_SERVER,
            To      => $EMAIL_TO,
            Cc      => 'me@my.com',
            From    => $EMAIL_FROM,
            Subject => 'testing',
        Message => $message,
           );
sendmail(%mail) or die $Mail::Sendmail::error;
[download]

The module is most likely not installed in the appropriate directory.

Read this node. It's for another module, but the problem is basically the same.

"Livet är hårt" sa bonden.
"Grymt" sa grisen...

Mail::Mailer is not available via PPM for ActivePerl so I guess that you must have either downloaded the tarball of MailTools and either install it manually (if you have nmake) or copied the files to the appropriate place - if you did that you will also need to have copied the smtp.pm,mail.pm,rfc822.pm and sendmail.pm into (if you have a similar setup as I do) C:\Perl\site\lib\Mail\Mailer. The Mail::Mailer::smtp (which you will almost certainly be using on windows as neither 'mail' or 'sendmail' will work :) also requires Mail::Utils but this is part of MailTools - unfortunately this does not work on Windows because it uses getpwuid which is not available there.

I would suggest that you use Net::SMTP until I have written the patch for MailTools that will overcome this problem.

(Sorry this is a bit patchy - I was going through the steps as I was typing :)

Update: I sent a patch to Mark Overmeer so that Mail::Mailer will work on Windows - as :

--- Util.pm~    Thu Feb  7 18:36:47 2002
+++ Util.pm     Thu Feb  7 19:08:20 2002
@@ -226,7 +226,7 @@

     $mailaddress ||= $ENV{USER}    ||
                      $ENV{LOGNAME} ||
-                     getpwuid($>)  ||
+                     eval { local $SIG{__DIE__}; scalar getpwuid($>);
+ }  ||
                      "postmaster";

     ##
[download]

/J\

For sending mail from multi-platforms (such as using a Windows 2000 Professional machine for testing, moving the code to Windows 2000 Advanced Server and then to a Linux box), I tend to use Mime::Lite. It's available via Activestate PPM (so it's extremely easy to install on a Windows machine), you can configure it to either Sendmail (if you've got it installed) or connect directly to your mail server, you can add 'attachments' and it's got plenty of example code for you to examine and try - one of the simplist ways that I use it is:

use Mime::Lite
MIME::Lite->send('smtp', $mail_server_name_or_ip_address, TimeOut=>60)
+;
my $msg=MIME::Lite->new (
 From=>"$from_name <$from_email_address>",
 To  =>"$to_email_address",
 Subject=>"$subject_of_email",
 Type=>'text',
 Data=>$body_of_email
);
$msg->send;
[download]

There is also Mail::Sender and Net::SMTP for you to consider. An example of Net::SMTP code is:

 use Net::SMTP
 my $smtp=Net::SMTP->new($mailserver_name_or_ip_address);
 $smtp->mail($from_address);
 $smtp->to($to_address);
 $smtp->data();
 $smtp->datasend("To: $to_address\n");
 $smtp->datasend("From: $from_address\n");
 $smtp->datasend("Subject: $message_subject\n");
 $smtp->datasend("\n$body_of_email\n");
 $smtp->dataend();
 $smtp->quit;
[download]

Best regards,
perl -le "s==*F=e=>y~\*martinF~stronat~=>s~[^\w]~~g=>chop,print"