Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

I'm trying to create a matrix (an array of arrays), and then store an array in each cell. The code I have so far... 
  my $rows = [];
  my $cols = [];
  my $results = [];
  my $table = [$rows, $cols, $results];

  ...snip...

  $table->[$row][$col] = @foo;

[download]
doesn't work (it takes @foo in a scalar context, whereas I want it to still be an array). I've tried using various combinations of [] and () with no success. Any thoughts?

Replies are listed 'Best First'.
Re: A Matrix of Arrays
by dvergin (Monsignor) on Feb 17, 2002 at 01:09 UTC
    Toss all that initialization stuff. It's not just unnecessary, it's wrong. Here's a demo to show you a full load/use cycle. 
    #!/usr/bin/perl -w
use strict;

# Build the table
my $table_ref;
for my $row (1..5) {
   for my $col (1..4) {
      my @results = rand_vals(4);
      $table_ref->[$row][$col] = \@results;
   }
}

# Use the table
for my $row (1..5) {
   for my $col (1..4) {
      print "[";
      
      # Let Perl walk through the array for us
      #for (@{$table_ref->[$row][$col]}) {
      #   print "$_ ";
      #}
      
      # Or index our way through the array explicitly
      for (0..$#{$table_ref->[$row][$col]}) {
         print "$table_ref->[$row][$col][$_] ";
      }
      
      print "] ";
   }
   print "\n";
}

# Just a little tool for demo purposes
sub rand_vals {
   my $elements = shift;
   my @ary;
   push @ary, int rand(9) for 1..$elements;
   return @ary;
}

    [download]
    Prints out something like: 
       [2 4 4 1 ] [8 6 2 5 ] [8 3 1 5 ] [6 5 3 7 ]
   [4 6 1 0 ] [6 6 6 2 ] [6 4 7 5 ] [8 2 6 8 ]
   [6 7 0 8 ] [7 8 6 2 ] [5 1 6 6 ] [1 7 8 3 ]
   [1 8 2 7 ] [7 8 2 1 ] [6 3 8 7 ] [2 2 6 4 ]
   [7 8 7 4 ] [5 8 4 7 ] [4 2 6 0 ] [3 2 3 5 ]

    [download]
    You can, of course, use the uncommented inner loop for accessing results values, or delete that loop and uncomment the other one. Whichever suits your needs.

    ------------------------------------------------------------
    "Perl is a mess and that's good because the
    problem space is also a mess.    " - Larry Wall

[reply]
[d/l]
[select]
Re: A Matrix of Arrays
by Zaxo (Archbishop) on Feb 17, 2002 at 00:52 UTC

    All you need is:

    $table->[$row][$col] = \@foo;

    [download]
    to be dereferenced by:
    my $foo = $table->[$i][$j][$k];

    [download]

    After Compline,
    Zaxo

[reply]
[d/l]
[select]
Re: A Matrix of Arrays
by theorbtwo (Prior) on Feb 17, 2002 at 00:51 UTC

    I think you're problem is that you're overinitilizing. Perl is very good at autovivification; let it do it.

    my @table;

foreach (0..Inf) {
 $table[$row][$col]=[qw(some list elements)];
}

    [download]

    We are using here a powerful strategy of synthesis: wishful thinking. -- The Wizard Book

[reply]
[d/l]
Re: A Matrix of Arrays
by Anonymous Monk on Feb 17, 2002 at 00:47 UTC
    Do you mean @{$table->[$row][$col]} = @foo;?
[reply]
[d/l]

Back to Seekers of Perl Wisdom