@version =
   map  { $_->[0] }
   sort { $a->[1][0] <=> $b->[1][0] ||
          $a->[1][1] <=> $b->[1][1] ||
          $a->[1][2] <=> $b->[1][2] }
   map  { [ $_, [ split '.', $_ ] ] }
      @versions;
[download]

------
We are the carpenters and bricklayers of the Information Age.

Don't go borrowing trouble. For programmers, this means Worry only about what you need to implement.

I like:

    my @sorted= map {
        s/\0(....)/unpack("N",$1)/gs
    } sort map {
        s/(\d)/"\0".pack("N",$1)/g
    } @versions;
[download]

See also Sorting on Section Numbers (which includes why Sort::Versions might not be the best choice) and How do I do a natural sort on an array?.

#!/usr/local/bin/perl

use strict;

my @versions=qw(2.0.0 1.0.9 1.0.10 1.1.0 1.1.2);

my @sversions = 
       map {$_->[0]} 
         sort {$a->[1] <=> $b->[1]} 
           map {
            my ($a1,$a2,$a3) = split(/\./,$_);
            [$_,$a1*1000000 + $a2*1000 + $a3]
           } @versions;
[download]

sub ST(&@){
        my $metric=shift;
        map {$_->[0]}
        sort {$a->[1] cmp $b->[1]}
        map {[$_,&{$metric}]} @_
}
my @versions = qw(2.0.0 1.0.9 1.0.10 1.1.0 1.1.2); 
@versions = ST {pack'C*',split/\./} @versions;
[download]

Though I have to supress 'is not numeric' warnings, a simple numeric sort seems to produce the order you want....

#!/usr/bin/perl -wT
use strict;

my @versions=qw(2.0.0 1.0.9 1.0.10 1.1.0 1.1.2 1.0.90);
my @sorted = do {no warnings 'numeric'; sort {$a <=> $b} @versions };

print "$_\n" for @sorted;

__END__

1.0.9
1.0.10
1.0.90
1.1.0
1.1.2
2.0.0
[download]

-Blake

Update 2: tye correctly pointed out that what I was trying to do (failing badly) was this:

sort{ eval "v$a" cmp eval "v$b" } @versions;
[download]

----

Since you have "version" strings, you can use the v notation to sort the strings, like this:

sort{ "v$a" cmp "v$b" } @versions;
[download]

It vorks like this: v2.0.0 is the same thing as chr(2).chr(0).chr(0), so we can do a stringwise compare, cmp and thus sort these correctly. The result is:

1.0.10
1.0.9
1.1.0
1.1.2
2.0.0
[download]

"v$a" does not a "vector" make (it just makes "v".$a). You'd have to use something like eval "v$a" for that. Even that won't work in the face of common version number formats like "1.0a".

Note that "10" is showing as less than "9" in your results.

        - tye (but my friends call me "Tye")

I noticed. I thought that was what was sought after, and stupidly did not crosscheck against what a direct cmp between the strings did - the same. I did realize my mistake... way too late. Better try to not be so triggerhappy in the future. :)

---

You have moved into a dark place.
It is pitch black. You are likely to be eaten by a grue.