• AddWin9x(%win9x); # not AddWin9x{%win9x};
• you probably want to pass the hash by reference though

  AddWin9x(\%win9x); # then extract the values inside the sub
  [download]

• on the last foreach you have { instead of ( also
• next inside a sub seems like bad form to me

Well that was dumb! Thanks! The second foreach was a typo for this post... Droped out the next. It bothered me everytime I looked at it and your comment motivated me. Have a good one!

There is no clean way to get that info via the registry so I decided to hard code the info in a hash of hash of lists.

I don't like spreading bad news, but a hash of lists is not really possible. A list of lists is neither.

Lists and arrays are different things. An array is mutable, but lists are not (lists are immutable ("read-only")). Consider:

# A list
(1, 2, 3);

# An array assignment (syntax: ARRAY = LIST)
my @array = (1, 2, 3);

# An array
@array

# The third element of the array
$array[2]

# The third element of a list (this actually is a slice)
(1, 2, 3)[2]

# Arrays are mutable, so the following is possible
$array[2]++

# Lists are immutable, so the following is impossible
(1, 2, 3)[2]++

# A reference to a named array
\@array

# A reference to an anonymous array
[ 1, 2, 3 ]

# A reference to a named array that later becomes anonymous
my $ref;
{
    my @array = (1, 2, 3);
    $ref = \@array;
}

# A list of references
\(1, 2, 3)

# Equal to \(1, 2, 3)
(\1, \2, \3)

# A list of arrays
([1, 2, 3], [4, 5, 6], [7, 8, 9])

# A reference to an (anonymous) array of (anonymous) arrays
[[1, 2, 3], [4, 5, 6], [7, 8, 9]]
[download]

U28geW91IGNhbiBhbGwgcm90MTMgY
W5kIHBhY2soKS4gQnV0IGRvIHlvdS
ByZWNvZ25pc2UgQmFzZTY0IHdoZW4
geW91IHNlZSBpdD8gIC0tIEp1ZXJk

IMO, an array is a list. A list may not be an array. An array is not just a list; it is a special type of list that has extra features. So "list of lists" is just fine, if more vague than necessary since any perl "list of lists" would more precisely be called a "list of references to arrays". But perllorta.pod probably isn't a better name.

I suppose you could define "list" such that it does not include "array". But that would be a very bad idea, IMO, and would conflict with a lot of the standard Perl documentation.

        - tye (but my friends call me "Tye")

IMO, an array is a list.

An array, when used in list context, evaluates to its elements. When used in scalar context, it evaluates to its number of elements. (You'll also notice that there is no "array context", just as there is no "hash context".) Consider:

# A list
(1, 2, 1, 2, 3);

# An array
@array;

# Array assignment (ARRAY = LIST)
@array = (1, 2, 1, 2, 3);

# List in list context
print (1, 2, 1, 2, 3); # 12123

# Array in list context
print @array; # 12123

# List in scalar context
print scalar (1, 2, 1, 2, 3); # 3 (not 5!!)

# Array in scalar context
print scalar @array; # 5 (not 3!!)
[download]


So in list context, an array evaluates to the same list that was used in its assignment (unless altered, of course), but in scalar context, a list evaluates to its last element and an array evaluates to its number of elements.


• You can change an array, you cannot change a list.
• An array knows its number of elements (MAX in the AV struct, internally), but a list does not.
• You can reference an array, but you cannot create a reference to a list (instead, a list of scalar references is made).
• An array is a data type suited for storage, a list is not.
</code>

U28geW91IGNhbiBhbGwgcm90MTMgY
W5kIHBhY2soKS4gQnV0IGRvIHlvdS
ByZWNvZ25pc2UgQmFzZTY0IHdoZW4
geW91IHNlZSBpdD8gIC0tIEp1ZXJk