my $sendmail = "/usr/sbin/sendmail";
open (MAIL, $sendmail) or die "cannot open sendmail";

You open sendmail for reading, which succeeds. The prints, however, do not succeed. It's not common to do, but you could write:

print MAIL "To: Adminmail\n" or die $!;
[download]

Instead, you will have to open sendmail as a write-only pipe.

open MAIL, "| $sendmail" or die $!;
[download]

open MAIL, '|', $sendmail or die $!;
[download]

Sendmail expects the to-address on the command line, so it will still not work. You do NOT want that, so you're going to avoid it by putting "-t" on the command line instead. While you're at it, add "-oi" too, to avoid having to end with a single dot on a line.

my $sendmail = '/usr/sbin/sendmail -t -oi';
open MAIL, '|', $sendmail or die $!;
[download]

Of course, best is to use one of the many existing mailing modules instead.

U28geW91IGNhbiBhbGwgcm90MTMgY
W5kIHBhY2soKS4gQnV0IGRvIHlvdS
ByZWNvZ25pc2UgQmFzZTY0IHdoZW4
geW91IHNlZSBpdD8gIC0tIEp1ZXJk

Untested code using Mail::Sendmail to give you an idea why using a module is far better :)

#!/usr/bin/perl -wT

use strict;
use CGI;
use Mail::Sendmail;

my $q = new CGI;

my $name    = $q->param("name");
my $email   = $q->param("email");
my $message = $q->param("message");

# Config

my $adminmail = "admin\@yoursite.com";
my $from      = "whoever\@whatever.com";
my $subject   = "enter subject here";

# End config

my %mail = ( To      => "$adminmail",
             From    => "$from",
             Subject => "$subject",
             Message => "$message" );

sendmail(%mail) or die $Mail::Sendmail::error;

print $q->redirect("thanks.html") or die "Can't find thanks.html: $!\n
+";
[download]

Update: You should include Juerd's improvements listed below.

"$adminmail"

"$foo" is often very bad style. Consider it equal to '' . $foo . '', and just write it without quotes instead. Also, using single quotes allows you to write @ signs without escaping them (style advice: use double quotes only if you use their's specialties (read perlop)).
You use %mail just once, and could have put that in the sub itself.

In my style, this script would be:

#!/usr/bin/perl -w

# Well, to be completely honest: I don't like CGI.pm, and wouldn't use
+ it.
# I will for now, because I'm just rewriting :)
# You may have noticed I removed the tainting checks too.

use strict;
use CGI;
use Mail::Sendmail;

my $q = CGI->new(); # Updated as per particle's excellent observation

my $name    = $q->param('name');    # Note: used only once
my $email   = $q->param('email');   # Note: only used once
my $message = $q->param('message'); # # Note: couldn't choose ;)

# Config

my $adminmail = 'admin@yoursite.com';
my $from      = 'whoever@whatever.com'; 
my $subject   = 'enter subject here';

# End config

sendmail(
    To      => $adminmail,
    From    => $from,
    Subject => $subject,
    Message => $message
) or die $Mail::Sendmail::error;

# Note: redirects should be absolute
# (All modern browsers handle relative redirects, though)

print $q->redirect('thanks.html') or die "Can't find thanks.html: $!\n
+";
[download]

U28geW91IGNhbiBhbGwgcm90MTMgY
W5kIHBhY2soKS4gQnV0IGRvIHlvdS
ByZWNvZ25pc2UgQmFzZTY0IHdoZW4
geW91IHNlZSBpdD8gIC0tIEp1ZXJk

umm... am i missing something, or should that my $q = CGI->; actually have a method call on the end, like my $q = CGI->new();?

~Particle ;Þ

Thanks Juerd! I do have one question for you. How do you specify the location of SENDMAIL in your version? I cannot see where you are actually telling it where it is, all you do is call sendmail. Thanks! sulfericacid

print MAIL "Name: $formdata{'name'}\n";  
print MAIL "email: $formdata{'email'}\n";
print MAIL "message: $formdata{'message'}\n";
[download]

print MAIL "Name: $formdata{name}\n"; 
print MAIL "email: $formdata{email}\n";
print MAIL "message: $formdata{message}\n";
[download]

Lastly.. I don't think those single quotes should be there. I'm not sure why they are there, and I would try removing them.

A hash key is a string, so it can be quoted. It's actually an exception to strict's strictness that you can do without quotes (only if it's a valid unquoted string, of course (/^\w+\z/). Same goes for =>'s left operand. Without strict, you can use unquoted strings everywhere (but don't drop strict, and don't use unquoted strings when not a hash key, or =>'s left operand).

/me prefers literal hash keys quoteless.

U28geW91IGNhbiBhbGwgcm90MTMgY
W5kIHBhY2soKS4gQnV0IGRvIHlvdS
ByZWNvZ25pc2UgQmFzZTY0IHdoZW4
geW91IHNlZSBpdD8gIC0tIEp1ZXJk

While we're at it, here is some general comments about your code:

• You declare a global in a subroutine. This sort of loose coupling is a big no-no, because it makes subtle bugs, and makes code more confusing. Consider returning the hash
• You then take the %formdata hash and after generating it say my %formdata. Apart from the fact that Globals R Bad, this is a extraneous construct. You can get rid of it.
• As has been mentioned, use a module to handle the sending of mail. It's more complicated than it looks (and it looks complicated). The module will save you the headache.
• There is no need to iterate through each param to build your hash. CGI.pm provides a method which will give you a hash straight off, and thus be more efficient and let you get rid of the sub all together.
• You use strict. Nice. But you also might want to use warnings, and most definately turn on -T for tainting, to ensure that your programs stay secure. You should do this at least for EVERY CGI program you write.

I also just want to say that you've come a long way since your early work you asked everyone in th CB to bugcheck. keep learning.

Cheers,
Erik

Looking at production code that was written by experts and that already works can be most illuminating.

--t. alex

"Here's the chocolates, and here's the flowers. Now how 'bout it, widder hen, will ya marry me?" --Foghorn Leghorn