Here's a general routine that will tell you if a particular branch of a hash exists. In otherwords, if you have this:

    $hash{ foo }{ bar }{ baz }
[download]

It can be a pain to check for the existence of every single key.

use strict;
use warnings;
use Data::Dumper;

my %hash = (
    one => {
        test => 3
    },
    two => {
        Ovid => {
            is => {
                a => 'fool'
            }
        }
    }
);

if ( hash_branch_exists( \%hash, qw/ one test / ) ) {
    print "Good\n";
} else {
    print "Bad\n";
}

if ( hash_branch_exists( \%hash, qw/ Ovid is a fool / ) ) {
    print "Good\n";
} else {
    print "Bad\n";
}

if ( hash_branch_exists( \%hash, qw/ two Ovid Is a / ) ) {
    print "Good\n";
} else {
    print "Bad\n";
}

sub hash_branch_exists {
    my ( $hash_ref, @fields ) = @_;

    foreach ( @fields ) {
        return 0 if ref $hash_ref ne 'HASH';
        return 0 if ! exists $hash_ref->{ $_ };
        $hash_ref = $hash_ref->{ $_ };
    }
    return 1;
}
[download]

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just click on the the link and check out our stats.

  DB<1> $a{foo}->{bar} = "zoikes"

  DB<2> print "yup\n" if exists $a{foo}
yup

  DB<3> print "yup\n" if exists $a{foo}->{bar}
yup

  DB<4> print "yup\n" if exists $a{foo}->{baz}

  DB<5> print "yup\n" if exists $a{foo} && exists $a{foo}->{bar}
yup

  DB<6> print "yup\n" if exists $a{foo} && exists $a{foo}->{baz}

  DB<7>
[download]

$a{foo}{bar} = 'blah';

print "Yep\n" if exists $a{foo} && $a{foo}{bar};
print "Nope\n" if exists $a{bar}{baz};
print "Whoops!\n" if exists $a{bar};
[download]

------
We are the carpenters and bricklayers of the Information Age.

Don't go borrowing trouble. For programmers, this means Worry only about what you need to implement.

You've created $a{bar} by your second check, just as perldoc -f exists explains.

Although the deepest nested array or hash will not spring into existence just because its existence was tested, any intervening ones will. Thus "$ref->{"A"}" and "$ref->{"A"}->{"B"}" will spring into existence due to the existence test for the $key element above. This happens anywhere the arrow operator is used, including even:...

#!/usr/bin/perl

my $skip_users = &get_data;
&print_data;

sub get_data
{
    my %skip_users;
    my $skip_id = 'fred';
    my $value = 'ethel';
    #build a hoh with userid and value.
    $skip_users{$skip_id}{$value}++;

    return(\%skip_users);
}

sub print_data
{
    my %hoh = %$skip_users;
    my $user = 'fred';
    my $command = 'thel';
    if ((exists $hoh{$user}) && (exists $hoh{$user}{$command})) {
        print "yep\n";
    } else {
        print "nope\n";
    }
}

sub print_data
{
    my %hoh = %$skip_users;    
    next if ((exists $hoh{$user}) && (exists $hoh{$user}{$command}));
}
[download]

Do you mean:

  print $hoh{$user}{$command}
    if ((exists $hoh{$user}) && (exists $hoh{$user}{$command}));
[download]

/prakash