All you need to do is make Astro::Observation the factory. It will return a class depending on what argument it receives. Here is a simple way to implement Astro::Observation:

package Astro::Observation;

use Astro::Observation::Simple;
use Astro::Observation::Complex;

sub new {
  my $self  = shift;
  my $class = shift;

  return Astro::Observation::Simple->new(@_)  if 'simple' eq $class;
  return Astro::Observation::Complex->new(@_) if 'complex' eq $class;
  return undef;
}
[download]

my $obs = Astro::Observation->new("simple",'foo');
my $obc = Astro::Observation->new("complex",'bar');
[download]

UPDATE: once again - just do what the wise and resourceful Kanji said.

UPDATE x 2: that's what i was trying to do! :D
Here is a tar ball should anyone want to try this out.

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

As it happens, merlyn posted something similar the other day, which you could adapt easily (untested)...

# in Astro::Observation

sub new {
    my $self  = shift;

    # Foo->new('bar',@_) => Foo::Bar->new(@_)

    my $class = __PACKAGE__ . "::" . ucfirst(shift);

    require autouse;
    autouse->import( $class, "$class\::new" );

    return $class->new( @_ );
}
[download]

Update:

... or not.

After trying out the above, I kept getting the error "autouse into different package attempted", which appears to be a known bug in autouse when using a module that isn't at the root of it's namespace (ie, Foo would work, but Foo::Bar doesn't).

Perhaps merlyn has a patched version of autouse?

Anyhoo, another way to do it (and as jeffa suggests) is with eval...

sub new {
    my $self  = shift;

    # Foo->new('bar',@_) => Foo::Bar->new(@_)

    my $class = __PACKAGE__ . "::" . ucfirst(shift);

    eval "require $class;"; # Note: "" *NOT* {} !

    if ( $@ ) {      # whoops, there was an error
        warn( $@ );  # require'ing $class; perhaps
        return;      # it doesn't exist?
    }

    return $class->new( @_ );
}
[download]

    --k.

This is expensive and dangerous:

eval "require $class;"; # Note: "" *NOT* {} !
[download]

whereas this is cheaper and safer (no firing up of the compiler):

(my $file = $class) =~ s#/#::#g;
require $file;
[download]

Please note that for future programs. (Yes, portabilty to macs and VMS is sacrificed.. for that, pull down File::Spec. But this works on Unix and Windows.)

-- Randal L. Schwartz, Perl hacker

Don't you mean something like this instead?

(my $file = $class) =~ s^::^/^g;
require "$file.pm";
[download]

Now, this seems to work using file spec:

my $file = File::Spec->catfile( split /::/, $class ) . ".pm";
[download]

Thanks for the time and tips,
LogicalChaos

jeffa, I notice that you may rid your code of

use Astro::Observation::Simple;
use Astro::Observation::Complex;
[download]

Thanks again,
LogicalChaos

More logical than chaotic now.