Slicing a reference?

drix has asked for the wisdom of the Perl Monks concerning the following question:

Relevant code; $dbh is a DBI database handle and Tr, td are from the CGI module:

foreach (@{$dbh->selectall_arrayref("SELECT * FROM search_atoms WHERE 
+occurences >= 5 ORDER BY occurences DESC")}) {
    print Tr( td({'-align' => 'left'}, [ $_->[0 .. 3] ] ) );
}
[download]

If it's second argument is an array ref, td is supposed to iterate over it. So there should be four <td>blah</td>'s here as I'm trying to slice the first four elements of the anonymous array that's being extracted out of the selectall_arrayref statement. So basically this is saving me the trouble of writing print Tr( td({'-align' => 'left'}, [ $_->[0],$_->[1],$_->[2],$_->[3] ] ) ); Lazy, am I? Yes. But there error I'm getting is most frustrating; this bit of code causes Perl to segfault every time. Is slicing a referent list verboten? What's the correct way to do this.

Comment on Slicing a reference? Select or Download Code

Replies are listed 'Best First'.

Re: Slicing a reference?
by Kanji (Parson) on Apr 05, 2002 at 03:31 UTC

It's not verboten, but it can get ugly. :-)

What you're looking for is @$_[0..3] which does a slice of $_ after you dereference it.

On a different note, have you given any thought to explicitly naming the columns you want to return rather than using SELECT *?

If your schema ever changes, @$_[0..3] might not contain what you think it should, but if you did something like this ...

my $rows = $dbh->selectall_arrayref("
  SELECT   foo, bar, baz, quux
  FROM     search_atoms 
  WHERE    occurences >= 5 
  ORDER BY occurences DESC
");

foreach ( @$rows ) {
    print Tr( td( {'-align' => 'left'}, $_ ) );
}
[download]

... each row would only contain what you need and expect, along with the pleasant side effect of not needing to slice up a reference.

--k.

[reply]
[d/l]

(crazyinsomniac) Re: Slicing a reference?
by crazyinsomniac (Prior) on Apr 05, 2002 at 03:27 UTC

perl -le"print for @{[1,2,3,4,5,6]}[2..5]"
perl -le"$_=[1..7];print for @{$_}[-1,-2]"
[download]

update:

# also, to give you some insight
perl -le"@_=(1..7);print for $_[-1,-2]"
perl -le"$_=[1..7];print for $_->[-1,-2]"

# and
perl -MO=Deparse -le"$_=[1..7];print for $_->[-1,-2]"

$_ = [(1, 2, 3, 4, 5, 6, 7)];
foreach $_ ($$_['???', -2]) {
    print $_;
}

# and
perl -MO=Deparse -le"@_=(1..7);print for $_[-1,-2]"
@_ = (1, 2, 3, 4, 5, 6, 7);
foreach $_ ($_['???', -2]) {
    print $_;
}

#and
perl -MO=Deparse -le"$_=[1..7];print for @$_[-1,-2]"

$_ = [(1, 2, 3, 4, 5, 6, 7)];
foreach $_ (@$_[-1, -2]) {
    print $_;
}
[download]

______crazyinsomniac_____________________________
Of all the things I've lost, I miss my mind the most.
perl -e "$q=$_;map({chr unpack qq;H*;,$_}split(q;;,q*H*));print;$q/$q;"

[reply]
[d/l]
[select]

Re: Slicing a reference?
by shotgunefx (Parson) on Apr 05, 2002 at 03:35 UTC

[@{$_}[0..3]]
[download]

[reply]
[d/l]

(tye)Re: Slicing a reference?
by tye (Sage) on Apr 05, 2002 at 23:38 UTC

I find that References quick reference makes these syntax hoops very easy to remember.

tye

[reply]