OO is easy to understand once you get your head around the basic concepts. First you create an object using the constructor (almost always called 'new') and store it in a scalar like $obj. Then you call methods on that object using the -> notation. A 'callback' is a reference to a sub that you want to run every time an event happens (like your method finds an email address).

Try these tutorials perlman:perlobj and perlman:perltoot

# make a new object of type 'Object' and pass it a callback sub
my $obj = new Object( sub{print "Hello World"} );

# call a method on that object
$obj->method;

# when we 'use' an OO module we effectively just add its packages to o
+ur code
# so lets just write a little package here that has a callback sub
package Object;
use Data::Dumper;

sub new { 
    my $class    = shift;
    my $callback = shift;
    my $anon_ref = { 'callback' => $callback };
    # make object by blessing our anon hash into $class
    my $object   = bless $anon_ref, $class;
  return $object;
}

sub method {
   my $self = shift;
   print "This is what \$self looks like:\n\n", Dumper($self), "\n\n";
   print "And here is our callback sub in operation\n\n";
   &{$self->{'callback'}};
}
[download]

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

#!/usr/bin/perl -w

our $MAILBOX = './mail/addresses';

use strict;
use Email::Find;
use IO::File;

# Read the mailbox
my $fh = IO::File->new($MAILBOX)
  or die "unable to read mailbox '$MAILBOX': $!";
my $mail;
{
  local $/;
  $mail = <$fh>;
}

# Find addresses
my %addy;
my $finder = Email::Find->new(
  sub {
    my($email, $orig_email) = @_;

    $addy{ $email->address }++;
    return $orig_email;
  }
);
$finder->find(\$mail);

foreach my $address (keys %addy) {
  print "$address $addy{ $address }\n";
}
[download]

You just needed to read the mailbox file so you could pass it to the find() method.

You should also become familiar with the Mail::Address module, since that's what is passed to your callback routine.

You didn't indicate what you actually wanted to do with the addresses, so in this example I'm just storing them in a hash.